Question

我想使用具有类型签名的函数将调试打印添加到我的项目中：

bool -> Printf.TextWriterFormat<'a> -> 'a

即。它应该采取一个bool来表明我们是否处于详细模式，并使用它来决定是否打印。

例如，让我们说dprint : bool -> Printf.TextWriterFormat<'a> -> 'a然后我想要这种行为：

> dprint true "Hello I'm %d" 52;;
Hello I'm 52
val it : unit = ()
> dprint false "Hello I'm %d" 52;;
val it : unit = ()

这个想法是可以使用命令行标志来避免控制此输出。我还想避免“非冗长”情况下的运行时成本。可以使用kprintf：

定义一个像这样工作的函数

let dprint (v: bool) (fmt: Printf.StringFormat<'a,unit>) =  
  let printVerbose (s: string) =
    if v then System.Console.WriteLine(s)

  fmt |> Printf.kprintf printVerbose

但打印/忽略List.iter (dprint b "%A") [1..10000]（b \ in {true，false}）的数字序列，对于我机器上的两个b值都需要1.5s。

我提出了另一种使用反射的方法，该方法构建一个适当类型的函数来丢弃格式化参数：

let dprint (v: bool) (fmt: Printf.TextWriterFormat<'a>) : 'a =
  let rec mkKn (ty: System.Type) =
    if FSharpType.IsFunction(ty) then
      let _, ran = FSharpType.GetFunctionElements(ty)
      FSharpValue.MakeFunction(ty,(fun _ -> mkKn ran))
    else
      box ()
  if v then
    printfn fmt
  else
    unbox<'a> (mkKn typeof<'a>)

但是这里的反思似乎太昂贵了（甚至比标准库中有时复杂定义的printf更多）。

我不希望用以下内容丢弃我的代码：

if !Options.verbose then
    printfn "Debug important value: %A" bigObject5

或关闭：

dprint (fun () -> printfn "Debug important value: %A" bigObject5)

那么，还有其他解决方案吗？

Answer 1

我喜欢使用反射的解决方案。如何在类型级别缓存它，以便每种类型只支付一次反射价格？例如：

let rec mkKn (ty: System.Type) =
    if Reflection.FSharpType.IsFunction(ty) then
        let _, ran = Reflection.FSharpType.GetFunctionElements(ty)
        // NOTICE: do not delay `mkKn` invocation until runtime
        let f = mkKn ran
        Reflection.FSharpValue.MakeFunction(ty, fun _ -> f)
    else
        box ()

[<Sealed>]
type Format<'T> private () =
    static let instance : 'T =
        unbox (mkKn typeof<'T>)
    static member Instance = instance

let inline dprint verbose args =
    if verbose then
        printfn args
    else
        Format<_>.Instance

实用主义者只会使用快速的C＃格式化打印机器而不是这个。我指出，由于它们的开销，我在生产代码中避免使用Printf函数。但是F＃打印肯定会更好用。

#time的{{1}}结果：

原始版本：0.85
带反射的原始版本：0.27
建议版本：0.03

Answer 2

这个怎么样：

/// Prints a formatted string to DebugListeners.
let inline dprintfn fmt =
    Printf.ksprintf System.Diagnostics.Debug.WriteLine fmt

然后你可以写：

dprintfn "%s %s" "Hello" "World!"

Debug.WriteLine(...)标有[<Conditional("DEBUG")>]，因此F＃编译器应能够在编译时消除整个语句（尽管您必须进行实验和检查已编译的IL以查看它是否确实存在。

请注意，此解决方案仅在您不关心在运行时更改详细程度时才有效。如果是这种情况，您将不得不寻找不同的解决方案。

更新：出于好奇，我只是尝试了这个代码（它确实有效），并且F＃2.0编译器不会编译所有内容（即使进行了优化），因此无论调试与否，速度都是相同的。可能还有其他方法可以让编译器消除整个语句来修复速度问题，但是您只需要进行一些实验就可以找到答案。

Answer 3

为什么不使用#defines来做

let dprint  (fmt: Printf.StringFormat<'a,unit>) =  
#if DEBUG
  let printVerbose (s: string) =
        System.Console.WriteLine(s)

  fmt |> Printf.kprintf printVerbose
#else
   fun _ -> ()

在我的机器上，样本测试在优化版本

中需要0.002秒

如何在F＃中管理调试打印

3 个答案: