Question

我有一个ListView和一个GridView。想象一下：第一个视图显示类别，第二个视图显示每个类别的文章。我希望在ListView的当前索引通过javascript更改时动态更改GridView的数据模型。我们怎么做？

Answer 1

您只需要指定一个新模型。这是一个基于ListModel文档的示例。此模型在左侧的ListView中显示模型中的水果。单击委托时，它会将右侧GridView的模型设置为attributes角色定义的列表。

import QtQuick 1.0

Item {
    width: 600; height: 400

    ListView {
        width: 300; height: 400
        model: fruitModel
        delegate: Text {
            font.pixelSize: 20
            text: name
            width: 300
            MouseArea {
                anchors.fill: parent
                onClicked: grid.model = attributes
            }
        }
    }

    GridView {
        id: grid
        x: 300; width: 300; height: 400
        delegate: Text {
            text: description
            font.pixelSize: 20
        }
    }

    ListModel {
     id: fruitModel

     ListElement {
         name: "Apple"
         cost: 2.45
         attributes: [
             ListElement { description: "Core" },
             ListElement { description: "Deciduous" }
         ]
     }
     ListElement {
         name: "Orange"
         cost: 3.25
         attributes: [
             ListElement { description: "Citrus" }
         ]
     }
     ListElement {
         name: "Banana"
         cost: 1.95
         attributes: [
             ListElement { description: "Tropical" },
             ListElement { description: "Seedless" }
         ]
     }
    }
}

这是嵌套模型的一个示例，但还有其他可能性。例如，如果您从数据库中获取数据，可能只需要更改GridView模型使用的查询，而不是设置不同的模型。

Answer 2

取决于您的型号。假设CategoriesModel有category个角色，ArticlesModel有setCategory方法：

ListView {
    model: CategoriesModel {}
    delegate: Item {
        MouseArea {
            anchors.fill: parent
            onClicked: {
                grid_view.model.setCategory(model.category)
            }
        }
        // ...
    }
}

GridView {
    id: grid_view
    model: ArticlesModel {}
    // ...
}

通过javascript更改QML GridView模型

2 个答案: