Question

成为Perl和XML的新手。任何人都可以指导我做以下事情：我必须写一个应该执行的Perl代码：

建立联系。
获取connectionId连接的响应，并将其存储在变量中。
关闭连接

输入：

应发布XML请求。请求类型为http。

我和我一起使用的XML语法。

任何人都可以指导我应遵循哪些步骤来满足上述要求。

提前致谢

添加代码：

use LWP::UserAgent;
use HTTP::Request::Common;
# The xml_request
my $xml_req = "<?xml version=1.0 encoding UTF-8?>
            <!ELEMENT drl (openconnection)>
            <!ATTLIST drl
             mode normal
             connectionid null
            >
            <!ELEMENT openconnection EMPTY>
            <!ATTLIST openconnection
            username admin
            password admin
            ></drl>";
my $ua = LWP::UserAgent->new();
my $response = $ua->post("http://XX.X.X.X:XXXX/lab/v1_2/connection/openConnectionRequest.dtd", Content => $xml_req);

输出是一个哈希值，但是如果它应该返回并且id是一个no ..我会出错？

Answer 1

根据您的请求的性质（大小，内容，结构取决于输入的程度），有几种不同的方法可以做到这一点。

最简单的方法是将您的请求存储在程序中的字符串中，将变量放入然后发送。

#!/usr/bin/perl
use strict; use warnings;
use LWP::UserAgent;

my ($param1, $param2) = (1, 2);

my $xml = <<XMLREQUEST
<request>
  <param1>$param1</param1>
  <param2>$param2</param2>
</request>
XMLREQUEST
;

my $ua = LWP::UserAgent->new;
my $response = $ua->post('http://www.yourdomain.com/', Content => $xml);
if ($response->is_success) {
  print $response->decoded_content;  # or whatever
}
else {
  die $response->status_line;
}

在这种情况下，我们正在使用LWP::UserAgent为我们发送/接收。

下一步是使用模板引擎。可以使用Text::Template来执行此操作。我们的示例代码如下所示：

#!/usr/bin/perl
use strict; use warnings;
use LWP::UserAgent;
use Text::Template;

my $vars = {
  'username' => 'jon',
  'password' => 'verysecure',
  'param1' => {
    'content' => 'a lot of content for param1',
    'foo'     => 'fofofofooo',
  },
  'param2' => {
    'content' => 'even more of content for param2',
    'bar'     => 'bar bar bar',
  },
  'param3' => {
    'content' => 'some content for param3',
  },
};

my $template = Text::Template->new(TYPE => 'FILEHANDLE', SOURCE => \*DATA );
my $xml = $template->fill_in(HASH => $vars);  

my $ua = LWP::UserAgent->new;
my $response = $ua->post('http://www.yourdomain.com/', Content => $xml);
if ($response->is_success) {
  print $response->decoded_content;  # or whatever
}
else {
  die $response->status_line;
}

__DATA__
<request>
  <auth>
    <username>{$username}</username>
    <password>{$password}</password>
  </auth>
  <param1 foo="{$param1{'foo'}}">{$param1{'content'}}</param1>
  <param2 bar="{$param2{'bar'}}">{$param2{'content'}}</param2>
  <param3>{$param3{'content'}}</param3>
</request>

它需要$vars hashref并将其内容放在模板中的相应位置。模板显示$var->{'username'}的位置填写{$username}。在这种情况下，模板是从DATA部分读取的，该部分在程序下面指定。一个好方法是为每个请求类型设置一个模板文件。如果请求包含可选元素，Text::Template可以使用条件语句处理此问题（将Perl代码放在模板中）。

如果您更喜欢更动态的方法，请考虑使用XML::Simple来完成简单的任务。请记住，XML::Simple不是最好的XML模块。还有其他一些，如XML::Twig，更健壮。

#!/usr/bin/perl
use strict; use warnings;
use LWP::UserAgent;
use XML::Simple;

my $xmlHash = {
  'request' => {
    'auth' => [ 
      {
        'username' => 'jon', 
      },
      {
        'password' => 'verysecure',
      },
    ],
    'param1' => {
      'content' => 'a lot of content for param1',
      'foo'     => 'fofofofooo',
    },
    'param2' => {
      'content' => 'even more of content for param2',
      'bar'     => 'bar bar bar',
    },
    'param3' => {
      'content' => 'some content for param3',
    },
  }
};

my $xml = XMLout($xmlHash, KeepRoot => 1);  

my $ua = LWP::UserAgent->new;
my $response = $ua->post('http://www.yourdomain.com/', Content => $xml);
if ($response->is_success) {
  print $response->decoded_content;  # or whatever
}
else {
  die $response->status_line;
}

你应该仔细阅读XML::Simple的文档，因为有时它有点奇怪。

如果您要解析请求的回复（也是XML），那么XML::Simple也可用于此。 XMLin()可以解决问题。

如果您要实现一个非常复杂的Web服务，请查看SOAP::Lite或（如果您有一个大型WSDL文件）SOAP::WSDL。

如何在Perl -help中创建XML请求？

1 个答案: