Question

我有xml喜欢

<tr>
 <td class="x">1</td>
 <td class="x">2</td>
 <td>3</td>
 <td class="x">4</td>
 <td class="x">5</td>
 <td class="x">6</td>
 <td class="x">7</td>
</tr>

我希望结果使用xsl是：

\cont{1-2}
\cont{4-7}

我可以这样做吗？

Answer 1

此转换既短（25行）又高效（使用键）：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:key name="kFollowing" match="td[@class='x']"
  use="concat(generate-id(..),
              '+',generate-id(preceding-sibling::*
                                 [not(self::td and @class='x')][1])
              )"/>  

 <xsl:template match="/*">
  <xsl:variable name="vGroup" 
       select="key('kFollowing', concat(generate-id(),'+'))"/>
  <xsl:value-of select=
     "concat('\cont{{',$vGroup[1],'-',$vGroup[last()],'}}','&#xA;')"/>
  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="*/*">
  <xsl:variable name="vGroup" select=
   "key('kFollowing', concat(generate-id(..),'+', generate-id()))"/>
  <xsl:value-of select=
     "concat('\cont{{',$vGroup[1],'-',$vGroup[last()],'}}','&#xA;')"/>
 </xsl:template>

 <xsl:template match="td[@class='x']|text()"/>
</xsl:stylesheet>

应用于提供的XML文档时：

<tr>
    <td class="x">1</td>
    <td class="x">2</td>
    <td>3</td>
    <td class="x">4</td>
    <td class="x">5</td>
    <td class="x">6</td>
    <td class="x">7</td>
</tr>

产生了想要的正确结果：

  \cont{1-2}
  \cont{4-7}

Answer 2

有很好的方法可以做到这一点，并且有一些讨厌的方法。我没有足够的时间想出一个好方法，这怎么抓住你？：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ext="http://exslt.org/common">
<xsl:output method="text" indent="no"/>

<xsl:template match="/tr">
    <xsl:for-each select="td[@class='x']">
        <xsl:variable name="currentNum" select="number(text())"/>
        <xsl:variable name="prevNum" select="number(preceding-sibling::td[@class='x'][1]/text())"/>
        <xsl:if test="($currentNum - 1) != $prevNum and $currentNum &gt; 0 and following-sibling::td[@class='x']">
            <xsl:variable name="following" select="following-sibling::td[@class='x']"/>
            <xsl:if test="number($following[1]/text()) = ($currentNum + 1)">
            \cont{<xsl:value-of select="$currentNum"/>-<xsl:call-template name="findend">
                    <xsl:with-param name="start" select="$currentNum"/>
                <xsl:with-param name="nodes" select="$following"/>
                </xsl:call-template>}
            </xsl:if>
         </xsl:if>
    </xsl:for-each>    
</xsl:template>

<xsl:template name="findend">
    <xsl:param name="nodes"/>
    <xsl:param name="start"/>
    <xsl:variable name="current" select="number($nodes[1]/text())"/>
    <xsl:choose>
        <xsl:when test="count($nodes) &lt; 2">
            <xsl:value-of select="$current"/>
        </xsl:when>
        <xsl:when test="number($nodes[2]/text()) != ($current + 1)">
            <xsl:value-of select="$current"/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:call-template name="findend">
                <xsl:with-param name="nodes" select="$nodes[position() &gt; 1]"/>
                <xsl:with-param name="start" select="$current"/>
            </xsl:call-template>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

输出

\cont{1-2}
\cont{4-7}

我假设如果你只有一个号码，你不想继续，那么你就不会得到\ cont {1-1}，并且它们必须按顺序排列，并且它们必须是在class ='x'。

如果时间更长，你可以想出更漂亮的东西！

作为一个解释，它通过寻找一个td [@ class ='x']，其数字不等于前一个+ 1（即，没有数字或它不是连续的）。如果找到一个，它检查下一个数字是这个数字+ 1，以避免cont {1-1}的情况，然后它调用一个寻找并打印结束的递归模板

Answer 3

以下是一些使用密钥和模式的XSLT 1.0方法（但主要是为了避免复杂的模板匹配模式）：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="text"/>

<xsl:key name="k1" 
  match="td[@class = 'x'][preceding-sibling::*[1][self::td[@class = 'x']]]"
  use="generate-id(
         preceding-sibling::td[
           @class = 'x' and 
           not(preceding-sibling::*[1][self::td[@class = 'x']])
         ][1]
       )"/>

<xsl:template match="tr">
  <xsl:apply-templates select="td[@class = 'x' and not(preceding-sibling::*[1][self::td[@class = 'x']])]" mode="start"/>
</xsl:template>

<xsl:template match="td[@class = 'x']" mode="start">
  <xsl:text>\cont{</xsl:text>
  <xsl:value-of select="."/>
  <xsl:text>-</xsl:text>
  <xsl:apply-templates select="key('k1', generate-id())[last()]" mode="end"/>
</xsl:template>

<xsl:template match="td[@class = 'x']" mode="end">
  <xsl:value-of select="."/>
  <xsl:text>}&#10;</xsl:text>
</xsl:template>

</xsl:stylesheet>

该样式表适用于

<tr>
 <td class="x">1</td>
 <td class="x">2</td>
 <td>3</td>
 <td class="x">4</td>
 <td class="x">5</td>
 <td class="x">6</td>
 <td class="x">7</td>
</tr>

输出

\cont{1-2}
\cont{4-7}

Answer 4

我能想出的最简单的样式表解决了你的问题：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="td[not(preceding-sibling::*[1][self::td][@class='x'])]">
        <xsl:text>\cont{</xsl:text>
        <xsl:value-of select="."/>
        <xsl:text>-</xsl:text>
        <xsl:value-of select="following-sibling::td[
                not(following-sibling::*[1][self::td][@class='x'])][1]"/>
        <xsl:text>}&#10;</xsl:text>
    </xsl:template>
  <xsl:template match="td"/>
</xsl:stylesheet>

解释：首先，我们匹配其前一个兄弟本身不是td且td属性等于class的每个x 。这些是起始节点，因此我们使用它们的值作为每个序列的开始。

对于序列的结尾，我们使用下一个td，而不是紧随其后的兄弟td class x。

忽略所有其他节点。

XSL计算连续节点

4 个答案: