Question

对于字符串“aa \ nbb \ ncc”我想从左边的最后一个字母到第一个换行符（“a”）到多行字符串的末尾匹配，并期望

"aa\nbb\ncc" =~ qr/( . $ .+ )/xms匹配a\nbb\ncc

那个

"aa\nbb\ncc\n" =~ qr/( . $ .+ )/xms匹配a\nbb\ncc\n。

但我找不到"aa\nbb\ncc" =~ qr/( . $ .+ )/xms的匹配并为c\n匹配"aa\nbb\ncc" =~ qr/( . $ .+ )/xms。

使用qr/( . $ ..+ )/xms我得到了预期的结果（参见示例代码）。

Perl版本5.14.2。

任何人都可以对这种行为作出解释吗？

perldoc perlre：

   m   Treat string as multiple lines.  That is, change "^" and "$" 
       from matching the start or end of the string to matching the start 
       or end of any line anywhere within the string.

   s   Treat string as single line. That is, change "." to match any character 
       whatsoever, even a newline, which normally it would not match.

       Used together, as "/ms", they let the "." match any character whatsoever, 
       while still allowing "^" and "$" to match, respectively, just after and 
       just before ewlines within the string.

   \z  Match only at end of string

运行以下示例代码：

#!/usr/bin/env perl

use strict;
use warnings;

print "Multiline string : ", '"aa\nbb\ncc"', "\n\n";
my $str = "aa\nbb\ncc";

print_match($str, qr/( . $ )/xms);       # matches "a"
print_match($str, qr/( . $ . )/xms);     # matches "a\n"
print_match($str, qr/( . $ .. )/xms);    # matches "a\nb"
print_match($str, qr/( . $ ..+ )/xms);   # matches "a\nbb\ncc"
print_match($str, qr/( . $ .+ )/xms);    # NO MATCH ! Why ???
print_match($str, qr/( . $ .+ \z )/xms); # NO MATCH ! Why ???

print "\nMultiline string now with terminating newline : ", '"aa\nbb\ncc\n"', "\n\n";
$str = "aa\nbb\ncc\n";

print_match($str, qr/( . $ )/xms);       # matches "a"
print_match($str, qr/( . $ . )/xms);     # matches "a\n"
print_match($str, qr/( . $ .. )/xms);    # matches "a\nb"
print_match($str, qr/( . $ ..+ )/xms);   # matches "a\nbb\ncc\n"
print_match($str, qr/( . $ .+ )/xms);    # MATCHES "c\n" ! Why ???
print_match($str, qr/( . $ .+ \z)/xms);  # MATCHES "c\n" ! Why ???

sub print_match {
    my ($str, $regex) = @_;
    $str =~ $regex;
    if ( $1 ) {
        printf "--> %-20s matched : >%s< \n", $regex, $1;
    }
    else {
        printf "--> %-20s : no match !\n", $regex;
    }
}

输出是：

Multiline string : "aa\nbb\ncc"

--> (?^msx:( . $ ))      matched : >a<
--> (?^msx:( . $ . ))    matched : >a
<
--> (?^msx:( . $ .. ))   matched : >a
b<
--> (?^msx:( . $ ..+ ))  matched : >a
bb
cc<
--> (?^msx:( . $ .+ ))   : no match !

Multiline string now with terminating newline : "aa\nbb\ncc\n"

--> (?^msx:( . $ ))      matched : >a<
--> (?^msx:( . $ . ))    matched : >a
<
--> (?^msx:( . $ .. ))   matched : >a
b<
--> (?^msx:( . $ ..+ ))  matched : >a
bb
cc
<
--> (?^msx:( . $ .+ ))   matched : >c
<

Answer 1

这是一个错误。请通过运行perlbug命令行来报告。

$ perl -E'say "aa\nbb\ncc" =~ qr/( . $ .+ )/xms ? ">$1<" : 0'
0

$ perl -E'say "aa\nbb\ncc\n" =~ qr/( . $ .+ )/xms ? ">$1<" : 0'
>c
<

$ perl -v
...
This is perl 5, version 16, subversion 0 (v5.16.0) built for x86_64-linux
...

如您所说，它们应分别与"a\nbb\ncc"和"a\nbb\ncc\n"匹配。有与$相关的优化。其中一个似乎没有考虑/ms。

PS - 您可能对use re 'debug';感兴趣。

$ perl -Mre=debug -E'say "aa\nbb\ncc" =~ qr/( . $ .+ )/xms ? ">$1<" : 0'
Compiling REx "( . $ .+ )"
Final program:
   1: OPEN1 (3)
   3:   SANY (4)
   4:   MEOL (5)
   5:   PLUS (7)
   6:     SANY (0)
   7: CLOSE1 (9)
   9: END (0)
anchored ""$ at 2 minlen 2 
Matching REx "( . $ .+ )" against "aa%nbb%ncc"
   0 <> <aa%nbb%ncc>         |  1:OPEN1(3)
   0 <> <aa%nbb%ncc>         |  3:SANY(4)
   1 <a> <a%nbb%ncc>         |  4:MEOL(5)
                                  failed...
   3 <aa%n> <bb%ncc>         |  1:OPEN1(3)
   3 <aa%n> <bb%ncc>         |  3:SANY(4)
   4 <aa%nb> <b%ncc>         |  4:MEOL(5)
                                  failed...
   6 <aa%nbb%n> <cc>         |  1:OPEN1(3)
   6 <aa%nbb%n> <cc>         |  3:SANY(4)
   7 <aa%nbb%nc> <c>         |  4:MEOL(5)
                                  failed...
Match failed
0
Freeing REx: "( . $ .+ )"

无法理解多行正则表达式qr /（。$。+）/ xms的结果

1 个答案: