Question

我正在尝试转换此XML： -

<list>
  <unit>
    <data1>a</data1>
    <data2>b</data2>
    <data3>c</data3>
  </unit>
</list>

到此： -

<list>
  <unit>
    <category1>
      <data1>a</data1>
      <data2>b</data2>
    </category1>
    <category2>
      <data3>c</data3>
    </category2>
  </unit>
</list>

使用XSL。我正在使用以下XSL： -

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:s="some_namespace">


<xsl:template match="@*|node()">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()" />
  </xsl:copy>
</xsl:template>

<xsl:template match="//s:unit" xml:space="preserve">
  <xsl:copy>
  <category1>
    <xsl:apply-templates select="./s:data1"/>
    <xsl:apply-templates select="./s:data2"/>
  </category1>
  <category2>
    <xsl:apply-templates select="./s:data3"/>
  </category2>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

现在，这保留了内部的缩进，但是完全混乱了。名单。这就是我得到的： -

  <list>
<unit>
  <category1>
    <data1>a</data1>
    <data2>b</data2>
  </category1>
  <category2>
    <data3>c</data3>
  </category2>
</unit>
  </list>

我在这里缺少什么？

Answer 1

我在这里缺少什么？

我认为不应该弄乱XSLT处理器的默认缩进。

<xsl:output indent="yes"/>和<xsl:strip-space elements="*"/>的组合通常足以获得良好的缩进效果。

此转化：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="unit">
  <unit>
      <category1>
       <xsl:apply-templates select="*[not(position() >2)]"/>
      </category1>
      <category2>
       <xsl:apply-templates select="*[position() >2]"/>
      </category2>
  </unit>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档时：

<list>
      <unit>
        <data1>a</data1>
        <data2>b</data2>
        <data3>c</data3>
      </unit>
</list>

生成想要的，缩进的结果：

<list>
  <unit>
    <category1>
      <data1>a</data1>
      <data2>b</data2>
    </category1>
    <category2>
      <data3>c</data3>
    </category2>
  </unit>
</list>

使用以下七个XSLT处理器中的任何一个运行转换时会产生相同的结果：

AltovaXML（XML-SPY）。
.NET XslCompiledTransform。
.NET XslTransform。
Saxon 6.5.4。
Saxon 9.1.05（XSLT 2.0处理器）。
XQSharp / XMLPrime（XSLT 2.0处理器）。
AltovaXml（适用于XSLT 2.0）。

MSXML3 / 4/6的情况更复杂 - 这些XSLT处理器的缩进只包含一个换行符，因此每个元素都在一个新行上，但出现在开始行。

对于这些XSLT处理器，我使用以下两遍处理，第一遍是上面的转换，第二遍适用于Nikolai Grigoriev提出的第一遍 one of the XML pretty-printers 的结果并在 XSLT FAQ 维护的 Dave Pawson 网站中提供：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="urn:schemas-microsoft-com:xslt"
 exclude-result-prefixes="ext">
 <xsl:output method="xml"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="indent-increment" select="'   '" />

 <xsl:variable name="vrtfPass1">
  <xsl:apply-templates select="/*"/>
 </xsl:variable>

 <xsl:variable name="vPass1" select="ext:node-set($vrtfPass1)"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="/">
  <xsl:apply-templates select="$vPass1/*" mode="pass2"/>
 </xsl:template>


 <xsl:template match="unit">
  <unit>
      <category1>
       <xsl:apply-templates select="*[not(position() >2)]"/>
      </category1>
      <category2>
       <xsl:apply-templates select="*[position() >2]"/>
      </category2>
  </unit>
 </xsl:template>

  <xsl:template match="*" mode="pass2">
     <xsl:param name="indent" select="'&#xA;'"/>

     <xsl:value-of select="$indent"/>
     <xsl:copy>
       <xsl:copy-of select="@*" />
       <xsl:apply-templates mode="pass2">
         <xsl:with-param name="indent"
              select="concat($indent, $indent-increment)"/>
       </xsl:apply-templates>
       <xsl:value-of select="$indent"/>
     </xsl:copy>
  </xsl:template>

  <xsl:template match="comment()|processing-instruction()" mode="pass2">
     <xsl:copy />
  </xsl:template>

  <!-- WARNING: this is dangerous. Handle with care -->
  <xsl:template match="text()[normalize-space(.)='']" mode="pass2"/>

</xsl:stylesheet>

在同一个（提供的）XML文档（上面）上执行此转换时，生成的结果具有所需的缩进：

<?xml version="1.0" encoding="UTF-16"?>
<list>
   <unit>
      <category1>
         <data1>a
         </data1>
         <data2>b
         </data2>
      </category1>
      <category2>
         <data3>c
         </data3>
      </category2>
   </unit>
</list>

这些都是我的计算机上的XSLT处理器。我建议尝试最后的转换 - 它有可能用Xalan-C产生想要的结果。

请注意：

最后一个转换使用特定于MSXML的扩展函数xxx：node-set（），属于特定于MSXML的命名空间：

xmlns:ext="urn:schemas-microsoft-com:xslt"

对于Xalan，需要替换为：

xmlns:ext="http://exslt.org/common"

或者，如果不支持EXSLT，则使用本机Xalan命名空间：

xmlns:ext="http://xml.apache.org/xalan

在最后一种情况下，必须使用对ext:node-set()的调用来替换对ext:nodeset()函数的调用（请注意缺少的短划线）：

 <xsl:variable name="vPass1" select="ext:nodeset($vrtfPass1)"/>

保留XSL样式表中的空格

1 个答案: