我正在开发一个网页，该网页根据我无权更改的XML Feed发布演示时间表。
Feed看起来像这样：
<track name="Track 1">
<session name="Session 1" starttime="2012-06-06 10:45" endtime="2012-06-06 12:45">
<presentation name="Presentation 1">
...presentation info
</presentation>
<presentation name="Presentation 2">
...presentation info
</presentation>
</session>
<session name="Session 2" starttime="2012-06-06 10:45" endtime="2012-06-06 12:45">
<presentation name="Presentation 3">
...presentation info
</presentation>
<presentation name="Presentation 4">
...presentation info
</presentation>
</session>
<session name="Session 3" starttime="2012-06-07 08:45" endtime="2012-06-07 10:45">
<presentation name="Presentation 5">
...presentation info
</presentation>
<presentation name="Presentation 6">
...presentation info
</presentation>
</session>
</track>
目前，我正在进行<xsl:for-each select="session">循环以获取信息，但最终会输出重复的日期和时间。
我在解析实际日期和时间方面没有问题，因此我目前正在输出2012年6月6日; 10:45没有任何问题，但每次因为for-each而被重复，如下所示：
2012年6月6日
10：45-12：45
第1节：演示文稿1，演示文稿2
2012年6月6日
10：45-12：45
第2节：演示文稿3，演示文稿4
2012年6月7日：
8：45-10：45
第3节：演示文稿5，演示文稿6
我想要的是以某种方式拉出所有常见的日期时间，例如，输出如下：
2012年6月6日：
的 10：45-12：45 的
第1节：演示文稿1，演示文稿2
第2节：演示文稿3，演示文稿4
2012年6月7日：
8：45-10：45
第3节：演示文稿5，演示文稿6
供参考，这是我目前的实施：
<xsl:for-each select="session">
<h4>
<!-- output to Month, DD, YYYY -->
<xsl:call-template name="formatDate">
<xsl:with-param name="dateTime" select="@starttime" />
</xsl:call-template>
</h4>
<h5>
<!-- output time -->
<xsl:call-template name="formatTime">
<xsl:with-param name="dateTime" select="@starttime" />
</xsl:call-template> -
<xsl:call-template name="formatTime">
<xsl:with-param name="dateTime" select="@endtime" />
</xsl:call-template>
</h5>
<!-- session title -->
<h5><xsl:value-of select="@name"/></h5>
<!-- presentation title -->
<xsl:for-each select="presentation">
<xsl:value-of select="@name"/><xsl:element name="br"/>
</xsl:for-each>
</xsl:for-each>
日期时间格式化程序：
<!-- formatting dateTime -->
<xsl:template name="formatDate">
<xsl:param name="dateTime" />
<xsl:variable name="date" select="substring-before($dateTime, ' ')" />
<xsl:variable name="year" select="substring-before($date, '-')" />
<xsl:variable name="month" select="number(substring-before(substring-after($date, '-'), '-'))" />
<xsl:variable name="day" select="number(substring-after(substring-after($date, '-'), '-'))" />
<!-- output -->
<xsl:choose>
<xsl:when test="$month = '1'">January</xsl:when>
<xsl:when test="$month = '2'">February</xsl:when>
<xsl:when test="$month = '3'">March</xsl:when>
<xsl:when test="$month = '4'">April</xsl:when>
<xsl:when test="$month = '5'">May</xsl:when>
<xsl:when test="$month = '6'">June</xsl:when>
<xsl:when test="$month = '7'">July</xsl:when>
<xsl:when test="$month = '8'">August</xsl:when>
<xsl:when test="$month = '9'">September</xsl:when>
<xsl:when test="$month = '10'">October</xsl:when>
<xsl:when test="$month = '11'">November</xsl:when>
<xsl:when test="$month = '12'">December</xsl:when>
</xsl:choose>
<xsl:value-of select="' '" />
<xsl:value-of select="$day" />
<xsl:value-of select="', '" />
<xsl:value-of select="$year" />
</xsl:template>
<!-- formatting dateTime -->
<xsl:template name="formatTime">
<xsl:param name="dateTime" />
<xsl:value-of select="substring-after($dateTime, ' ')" />
</xsl:template>
答案 0 :(得分：1)
首先，避免在XSLT中使用for-each，而是将节点应用于模板。
尝试此操作（压缩，没有调用call-template，因为您没有发布该位），您可以在this XMLPlayground运行。
<!-- sessions -->
<xsl:template match='track/session'>
<xsl:if test='not(preceding-sibling::session[@starttime = current()/@starttime])'>
<h4><xsl:value-of select="@starttime" /></h4>
<h5><xsl:value-of select="concat(@starttime,' - ',@endtime)" /></h5>
<p><xsl:apply-templates select="presentation" /></p>
<xsl:variable name='other_pres' select="following-sibling::session[@starttime = current()/@starttime]/presentation" />
<xsl:if test='count($other_pres)'>
<p><xsl:apply-templates select="$other_pres" /></p>
</xsl:if>
</xsl:if>
</xsl:template>
<!-- presentations -->
<xsl:template match='presentation'>
<xsl:if test='position() = 1'>
<strong><xsl:value-of select='../@name' />: </strong>
</xsl:if>
<xsl:value-of select="@name"/>
<xsl:if test='position() != last()'>, </xsl:if>
</xsl:template>
这里的概念是，在session模板中，对于每个会话，我们首先看看我们之前是否已经处理了具有相同@starttime的会话（因为我认为这是属性你意味着负责复制）。如果是这样，我们跳过它。
然后，在输出会话的演示文稿（由他们自己的模板处理，您会注意到）时，我们还处理当前session的兄弟节点的任何演示。
Output （无法访问日期格式模板）
<h4>2012-06-06 10:45</h4>
<h5>2012-06-06 10:45 - 2012-06-06 12:45</h5>
<p><strong>Session 1: </strong>Presentation 1, Presentation 2</p><p><strong>Session 2: </strong>Presentation 3, Presentation 4</p>
<h4>2012-06-07 08:45</h4>
<h5>2012-06-07 08:45 - 2012-06-07 10:45</h5>
<p><strong>Session 3: </strong>Presentation 5, Presentation 6</p>
答案 1 :(得分：1)
您想使用Muenchian method进行分组。立即在样式表的根元素中添加：
<xsl:key name="sessions-by-track-name-starttime-and-endtime" match="/track/session" use="concat(parent::track/@name, ' ', @starttime, ' ', @endtime)"/>
然后如图所示更新您的XSLT：
<xsl:for-each select="session[generate-id() = generate-id(key('sessions-by-track-name-starttime-and-endtime', concat(parent::track/@name, ' ', @starttime, ' ', @endtime))[1])]">
<h4>
<!-- output to Month, DD, YYYY -->
<xsl:call-template name="formatDate">
<xsl:with-param name="dateTime" select="@starttime" />
</xsl:call-template>
</h4>
<h5>
<!-- output time -->
<xsl:call-template name="formatTime">
<xsl:with-param name="dateTime" select="@starttime" />
</xsl:call-template> -
<xsl:call-template name="formatTime">
<xsl:with-param name="dateTime" select="@endtime" />
</xsl:call-template>
</h5>
<xsl:for-each select="key('sessions-by-track-name-starttime-and-endtime', concat(parent::track/@name, ' ', @starttime, ' ', @endtime))">
<!-- session title -->
<h5><xsl:value-of select="@name"/></h5>
<!-- presentation title -->
<xsl:for-each select="presentation">
<xsl:value-of select="@name"/><xsl:element name="br"/>
</xsl:for-each>
</xsl:for-each>
</xsl:for-each>