Question

因此，对于我正在编写的程序，我希望它能够搜索目录中的所有子目录。如果子目录名称包含一个单词，让我们说“foo”，那么程序将打开该子目录并对子目录中的文件执行一个函数。任何人都可以帮我解决这个问题吗？它也需要递归。提前致谢

Answer 1

这可以使用File::Find模块完成，但我相信Path::Class是优越的，即使它不是核心模块，也可能需要安装。

此程序找到所需文件并调用process来处理它们。目前，process子例程只是打印文件的名称以供测试。

use strict;
use warnings;

use Path::Class;

my $dir = dir '/path/to/root/directory';

$dir->recurse(callback => sub {
  my $node = shift;
  return if $node->is_dir;
  my $parent = $node->parent;
  if ($parent->basename =~ /foo/) {
    process($node);
  }
});

sub process {
  my $file = shift;
  print $file, "\n";
}

<强>更新

如果您愿意，此程序使用File::Find执行相同的任务。

use strict;
use warnings;

use File::Find;
use File::Basename qw/ basename /;

my $dir = '/path/to/root/directory';

find(sub {
  return unless -f;
  if (basename($File::Find::dir) =~ /foo/) {
    process($File::Find::name);
  }
}, $dir);

sub process {
  my $file = shift;
  print $file, "\n";
}

<强>更新

根据要求，这是使用Path::Class::Rule进行比较的进一步解决方案。由于daxim建议代码稍短。

use strict;
use warnings;

use Path::Class::Rule;

my $rule = Path::Class::Rule->new;
$rule->file->and(sub { $_->parent->basename =~ /foo/ });

my $next = $rule->iter('/path/to/root/directory');
while ( my $file = $next->() ) {
  process($file);
}

sub process {
  my $file = shift;
  print $file, "\n";
}

Perl搜索特定的子目录然后进行处理

1 个答案: