Question

我刚开始使用Groovy。我确信我错过了一些愚蠢的东西。有人能告诉我为什么这个代码在groovy控制台中失败了吗？它认为输入字符串中只有14个单词和1行。

def input = """
line1: 50 65 42
line2: 123 456 352 753 1825
line3: 10 25 20 48 107
"""

words = input.split(/ /)
lines = input.split(/^/)
assert words.size() == 16
assert lines.size() == 3

Answer 1

对于第一个assert，错误消息可以提示问题所在：

Assertion failed: 

assert words.size() == 16
       |     |      |
       |     14     false
       [
       line1:, 50, 65, 42
       line2:, 123, 456, 352, 753, 1825
       line3:, 10, 25, 20, 48, 107
       ]

那里有一些逗号，并且打印words值的方式似乎不对。发生的事情是input.split(/ /)正在用空格分割输入字符串，但由于它还包含换行符，因此某些单词不会被拆分，例如'42\nline2:'。

为了更清楚地看到这一点，我们可以使用inspect方法，它为我们提供了一个字符串形式的字符串：

println input.inspect()
// --> '\nline1: 50 65 42\nline2: 123 456 352 753 1825\nline3: 10 25 20 48 107\n'

println input.split(/ /).inspect()
// --> ['\nline1:', '50', '65', '42\nline2:', '123', '456', '352', '753', '1825\nline3:', '10', '25', '20', '48', '107\n']

通过空格分割单词Groovy添加了一个方便的非参数化split方法：

def words = input.split()
assert words.size() == 16
println words.inspect()
// --> ['line1:', '50', '65', '42', 'line2:', '123', '456', '352', '753', '1825', 'line3:', '10', '25', '20', '48', '107']

要获取字符串的行，您可以使用readLines。

def lines = input.readLines()
println lines.inspect()
// --> ['', 'line1: 50 65 42', 'line2: 123 456 352 753 1825', 'line3: 10 25 20 48 107']

请注意，readLines将返回四个元素，因为有第一个空行（我不知道为什么它会忽略最后一个空行），所以assert lines.size() == 3仍然会失败

您可以在结果列表中使用Collection#findAll()过滤掉这些空行，或直接在输入字符串上调用String#findAll(Pattern)：

def lines = input.readLines().findAll()
assert lines.size() == 3

def lines2 = input.findAll(/\S+/)
assert lines2.size() == 3

assert lines == lines2

简单的Groovy控制台解析问题

1 个答案: