Question

具有以下文件结构 - 请参阅 DATA 部分：

#!/usr/bin/perl  
use strict;
use warnings;
use Text::Balanced qw(extract_bracketed);

my($ALL, $name, $pairs);
while(defined($name = <DATA>) && defined($pairs = <DATA>)) {
    $ALL->{$name} = parse_pairs($pairs);
}

sub parse_pairs {
    my $str = shift;

    my($extracted, $remainder) = extract_bracketed($str,'{}'); # how to?


}    
__DATA__
name1
key1 val1 key2 {val2a val2b} key3 val3
name2
key2 val2 key3 val3
name3
key1 {val1a val1b val1c} key2 {val2a val2b}

e.g。每个奇数行包含一个唯一的“名称”，每个偶数行包含多个“键值”对 - 空格分隔。

密钥总是一个字（\ w +）
值可以是：
- 一个字符串（\ S +）或
- 多个空格分隔的字符串，用方括号{}

需要将上述文件放入perl结构中：

$ALL => {
    name1 => {
        key1 => ["val1"],
        key2 => ["val2a", "val2b"],
        key3 => ["val3"]
    },
[.......]

或

$ALL => {
    name1 => {
        key1 => {
           val1 => undef,
        },
        key2 => {
           val2a => undef,
           val2b => undef,
        }
        key3 => {
           val3 => undef,
        }
    },
[.......]

这可能是 Text :: Ballanced的作业，但不知道如何使用它，因为这里有混合值，有些只是简单的单词，有些是平衡的 - 括号括起来，并且不知道如何重复提取。 ;（

需要一些提示，如何在上面的src中编写parse_pairs子。

Answer 1

这就是我所拥有的。但是，它不使用Text :: Balanced。它正在使用Regexp :: Common：

#!/usr/bin/perl  
use strict;
use warnings;
use Regexp::Common;

my($ALL, $name, $pairs);
while(defined($name = <DATA>) && defined($pairs = <DATA>)) {
    chomp $name;
    chomp $pairs;
    $ALL->{$name} = parse_pairs($pairs);
}
use Data::Dump; dd $ALL;

sub parse_pairs {
    my $str = shift;

    my @key_values = $str =~ /
        (\w+)    # key
        \s*
        (\w+|$RE{balanced}{-parens=>'{}'}) # value
        \s*/xg;

    my $r;
    while (@key_values)
    {
        $key_values[1] =~ s/^\{//;
        $key_values[1] =~ s/\}$//;
        $r->{$key_values[0]} = [ split /\s+/, $key_values[1] ];
        splice @key_values, 0, 2;
    }
    $r;
}
__DATA__
name1
key1 val1 key2 {val2a val2b} key3 val3
name2
key2 val2 key3 val3
name3
key1 {val1a val1b val1c} key2 {val2a val2b}

这似乎产生了你正在寻找的输出（选项1）。

在一行中解析多个关键字值对 - 混合分隔符 - Text :: Balanced

1 个答案: