Question

我在域类中有静态方法，返回一个url。我需要动态构建该URL，但g.link无法正常工作。

static Map options() {
    // ...
    def url = g.link( controller: "Foo", action: "bar" )
    // ...
}

我收到以下错误：

Apparent variable 'g' was found in a static scope but doesn't refer to a local variable, static field or class. Possible causes:
You attempted to reference a variable in the binding or an instance variable from a static context.
You misspelled a classname or statically imported field. Please check the spelling.
You attempted to use a method 'g' but left out brackets in a place not allowed by the grammar.
 @ line 17, column 19.
           def url = g.link( controller: "Foo", action: "bar" )
                     ^

1 error

显然我的问题是我试图从静态上下文中访问g，那么我该如何解决这个问题？

Answer 1

g对象是一个taglib，它在域类中不可用，就像它在控制器中一样。您可以通过此处显示的grailsApplication了解How To Call A Taglib As A Function In A Domain Class

在Grails 2+中执行此操作的更好方法是通过grailsLinkGenerator服务，如下所示：

def grailsLinkGenerator

def someMethod() {
    def url = grailsLinkGenerator.link(controller: 'foo', action: 'bar')
}

在这两种情况下，您都需要做一些额外的工作才能从静态上下文中获取grailsApplication / grailsLinkGenerator。最好的方法可能是将其从域类的domainClass属性中删除：

def grailsApplication = new MyDomain().domainClass.grailsApplication
def grailsLinkGenerator = new MyDomain().domainClass.grailsApplication.mainContext.grailsLinkGenerator

Answer 2

如果您使用的是Grails 2.x，则可以使用LinkGenerator API。这是一个例子，我正在重新使用我之前测试过的域类，所以忽略非url相关的功能。

class Parent {
    String pName

    static hasMany = [children:Child]

    static constraints = {
    }
    static transients = ['grailsLinkGenerator']

    static Map options() {
        def linkGen = ContextUtil.getLinkGenerator();
        return ['url':linkGen.link(controller: 'test', action: 'index')]
    }
}

具有静态方法的实用程序类

@Singleton
class ContextUtil implements ApplicationContextAware {
    private ApplicationContext context

    void setApplicationContext(ApplicationContext context) {
        this.context = context
    }

    static LinkGenerator getLinkGenerator() {
        getInstance().context.getBean("grailsLinkGenerator")
    }

}

新实用程序Bean的Bean Def

beans = {
    contextUtil(ContextUtil) { bean ->
        bean.factoryMethod = 'getInstance'
    }
}

如果您需要基本网址，请将absolute:true添加到链接调用中。

不能在域类中使用grails g.link

2 个答案: