Question

我需要动态地将上传的二进制文件转换为base64字符串格式。我正在使用ASP，Vbscript。使用Midori的组件进行base64转换。对于小尺寸文件（<20K），性能还可以。但当它超过75或100K时，它完全失去了。有没有有效的方法将大二进制文件（2MB）转换为base64字符串格式？

提前致谢，肯尼

Answer 1

我通过实现.net组件转换为base64字符串解决了这个问题。困难的部分是从ASP发送到.net COM的二进制数据作为字符串接收。 Convert.ToBase64（）只接受byte []。所以我尝试将字符串转换为byte []。

但.net（Unicode，ASCII，UTF）中可用的编码效果不佳。有数据丢失，而使用这些编码。最后，我通过使用StringReader对象完成它。通过char（16位）读取char并将它们转换为（8位）byte []数组。

表现最好。

此致希瓦。

Answer 2

你应该使用.NET方法Convert.ToBase64String和Convert.FromBase64String。

使用Convert.FromBase64String（）方法。这将为您提供二进制文件数据返回（作为字节数组）。

要将二进制数据转换为Base64字符串，请参阅从二进制数据到vbscript

中的字符串的转换函数

来自http://www.motobit.com/tips/detpg_Base64Encode/

Function Base64EncodeBinary(inData)
  Base64EncodeBinary = Base64Encode(BinaryToString(inData))
End Function

Function Base64Encode(inData)
  'rfc1521
  '2001 Antonin Foller, Motobit Software, http://Motobit.cz
  Const Base64 = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"
  Dim cOut, sOut, I

  'For each group of 3 bytes
  For I = 1 To Len(inData) Step 3
    Dim nGroup, pOut, sGroup

    'Create one long from this 3 bytes.
    nGroup = &H10000 * Asc(Mid(inData, I, 1)) + _
      &H100 * MyASC(Mid(inData, I + 1, 1)) + MyASC(Mid(inData, I + 2, 1))

    'Oct splits the long To 8 groups with 3 bits
    nGroup = Oct(nGroup)

    'Add leading zeros
    nGroup = String(8 - Len(nGroup), "0") & nGroup

    'Convert To base64
    pOut = Mid(Base64, CLng("&o" & Mid(nGroup, 1, 2)) + 1, 1) + _
      Mid(Base64, CLng("&o" & Mid(nGroup, 3, 2)) + 1, 1) + _
      Mid(Base64, CLng("&o" & Mid(nGroup, 5, 2)) + 1, 1) + _
      Mid(Base64, CLng("&o" & Mid(nGroup, 7, 2)) + 1, 1)

    'Add the part To OutPut string
    sOut = sOut + pOut

    'Add a new line For Each 76 chars In dest (76*3/4 = 57)
    'If (I + 2) Mod 57 = 0 Then sOut = sOut + vbCrLf
  Next
  Select Case Len(inData) Mod 3
    Case 1: '8 bit final
      sOut = Left(sOut, Len(sOut) - 2) + "=="
    Case 2: '16 bit final
      sOut = Left(sOut, Len(sOut) - 1) + "="
  End Select
  Base64Encode = sOut
End Function

Function MyASC(OneChar)
  If OneChar = "" Then MyASC = 0 Else MyASC = Asc(OneChar)
End Function

Answer 3

使用MSXML为您执行编码。这是封装过程的函数： -

 Function ToBase64(rabyt)

     Dim xml: Set xml = CreateObject("MSXML2.DOMDocument.3.0")
     xml.LoadXml "<root />"
     xml.documentElement.dataType = "bin.base64"
     xml.documentElement.nodeTypedValue = rabyt

     ToBase64 = xml.documentElement.Text

 End Function

请注意，这将包括base64编码中的换行符，但大多数base64解码器都可以容忍换行符。如果不是，你可以简单地使用Replace(base64, vbLF, "")删除它们，这仍然比纯VBScript解决方案更快。

修改示例用法： -

Dim sBase64: sBase64 = ToBase64(Request.BinaryRead(Request.TotalBytes))

Answer 4

我使用c＃的下一个代码：

    public static string ImageToBase64(Image image, ImageFormat format)
    {
        using (MemoryStream ms = new MemoryStream())
        {
            // Convert Image to byte[]
            image.Save(ms, format);
            byte[] imageBytes = ms.ToArray();

            // Convert byte[] to Base64 String
            string base64String = Convert.ToBase64String(imageBytes);
            return base64String;
        }
    }

    public static Image Base64ToImage(string base64String)
    {
        // Convert Base64 String to byte[]
        byte[] imageBytes = Convert.FromBase64String(base64String);
        MemoryStream ms = new MemoryStream(imageBytes, 0,
          imageBytes.Length);

        // Convert byte[] to Image
        ms.Write(imageBytes, 0, imageBytes.Length);
        Image image = Image.FromStream(ms, true);
        return image;
    }

对于vbscript，请参阅http://www.freevbcode.com/ShowCode.asp?ID=5248或许可以帮助您。

Answer 5

在base64-encode-string-in-vbscript中对此进行了很好的讨论。

此外，我发现this site对于试图提高vb代码的速度非常有用。对于vb6，有几种基础64的变体非常快。

Answer 6

这对我有用

Function Base64DataURI(url)

    'Create an Http object, use any of the four objects
    Dim Http
    Set Http = CreateObject("WinHttp.WinHttpRequest.5.1")

    'Send request To URL
    Http.Open "GET", url, False
    Http.Send
    'Get response data As a string and encode as base64
    Base64DataURI = Encrypt(Http.ResponseText)
End Function

在我的情况下，URL是一个动态生成条形码的脚本，需要进行编码以包含在电子邮件中。

加密是我们用来编码为Base64的非常标准的功能，但我们需要的主要概念是通过URL而不是文件系统获取文件。

将二进制文件转换为Base64字符串

6 个答案: