Question

我正在尝试将当前的Apache / Modperl站点转移到Starman，并且需要使用不同的处理程序构建app.psgi以用于不同的文件扩展名。像Apache一样的东西：

<LocationMatch "(\.m|\.mh|\/)$">
     SetHandler              perl-script
     PerlHandler             MyApp::Mhandler
</LocationMatch>

<LocationMatch "(\.p|\.ph)$">
     SetHandler              perl-script
     PerlHandler             MyApp::Phandler
</LocationMatch>

现在我有：

#app for handle .m and .mh
my $Mapp = Some::PSGI->handler( sub {
...
});

#app for handling .p and .ph
my $Papp = SomeOther::PSGI->handler( sub {
...
});

但如何使用构建器？

builder {

    #any extension what is not .m .mh .p .ph - handle as static
    #but, only when the request have any extension
    enable "Plack::Middleware::Static",
      path => __what here__, ???
      root => "/my/doc/root";

    #and what here to achieve the following "rules".

    #??? $Papp
    #default $Mapp
};

需要的“规则”：

如果请求没有有任何扩展名，或者请求以“/”结尾
- 应使用$Mapp
如果请求以某种扩展名结束，那么
- .m和.mh应由$Mapp
- .p和.ph应由$Papp
- 所有其他带扩展名的文件（如.css .js .pdf .jpg ...）都应该作为静态处理。

当然，将每个静态文件放入某个树会更容易，但当前的应用程序是给出的，现在我只想将它移动到Startman，重构 - 稍后。

Answer 1

use strictures;
use Plack::Request qw();
use Plack::Builder qw(builder enable);
use Tie::REHash do_cache => 1;

tie my %location_match, 'Tie::REHash';
%location_match = (
    qr'(\.m|\.mh|/|/[^.]+)$' => sub {[200,[],['Mhandler']]},
    qr'(\.p|\.ph)$'          => sub {[200,[],['Phandler']]},
);

my $app = sub {
    my ($env) = @_;
    my $req = Plack::Request->new($env);
    my $res;
    if ($location_match{$req->path_info}) {
        printf "path [%s] dispatches to %s\n", $req->path_info, $location_match{$req->path_info};
        $res = $location_match{$req->path_info};
    } else {
        die sprintf "no match for path [%s], check routing configuration\n", $req->path_info;
    }
    return $res->($env);
};

builder {
    enable 'Static', path => sub {
        my ($path) = @_;
        if ($location_match{$path}) {
            print "redispatch\n";
            return;
        } elsif ($path =~ qr'/ [^/]+ [.] [^/]+ $'x) {
            return 1;
        } else {
            die "no match for path [$path], check routing configuration\n";
        }
    }, root => './htdocs/';
    $app;
}

__END__
GET 'http://localhost:5000/foo?bar=baz;quux#fnord'
GET 'http://localhost:5000/foo/?bar=baz;quux#fnord'
GET 'http://localhost:5000/foo.m?bar=baz;quux#fnord'
GET 'http://localhost:5000/foo.mh?bar=baz;quux#fnord'
GET 'http://localhost:5000/foo.p?bar=baz;quux#fnord'
GET 'http://localhost:5000/foo.ph?bar=baz;quux#fnord'
GET 'http://localhost:5000/foo.css?bar=baz;quux#fnord'
GET 'http://localhost:5000/foo.js?bar=baz;quux#fnord'
GET 'http://localhost:5000/foo.pdf?bar=baz;quux#fnord'
GET 'http://localhost:5000/foo.jpg?bar=baz;quux#fnord'

将Modperl配置转换为Plack - 通过文件扩展名运行不同的处理程序

1 个答案: