Question

我在block中得到了我需要的xml元素。但同样，我也把块用于捕获其他xml元素。但它对我不起作用...

这是XML文档

<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<w:document xmlns:w="http://schemas.openxmlformats.org/wordprocessingml/2006/main">
<w:body>
    <w:p>
        <w:pPr>
        </w:pPr>
        <w:r>
            <w:t>Text1-</w:t>
        </w:r>  
    </w:p>

    <w:p>
        <w:pPr>
            <w:pStyle w:val="Heading1" /> 
        </w:pPr>
        <w:r>
            <w:t>Text2-</w:t>
        </w:r>  
    </w:p>

    <w:p>
        <w:pPr>
        </w:pPr>
        <w:r>
            <w:t>Text3-</w:t>
        </w:r>  
    </w:p>

    <w:p>
        <w:pPr>
        </w:pPr>
        <w:r>
            <w:t>Text4-</w:t>
        </w:r>  
    </w:p>

    <w:p>
        <w:pPr>
            <w:pStyle w:val="Heading1" /> 
        </w:pPr>
        <w:r>
            <w:t>Text5-</w:t>
        </w:r>  
    </w:p>

</w:body>
</w:document>

这是XSLT文件

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:w="http://schemas.openxmlformats.org/wordprocessingml/2006/main"
 exclude-result-prefixes="w">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="/">
    <Document>

      <xsl:variable name="headingName" select="(//w:body/w:p/w:pPr/w:pStyle[starts-with(@w:val, 'Heading')])[1]/@w:val"/>
      <xsl:variable name="topLevelHeadings" select = "//w:body/w:p[w:pPr/w:pStyle/@w:val = $headingName]"/>

      <xsl:choose>

        <xsl:when test="$topLevelHeadings">
          <Heading>
          <xsl:apply-templates select="$topLevelHeadings">
          </xsl:apply-templates>
          </Heading>
        </xsl:when>

        <xsl:otherwise>
             <xsl:apply-templates select="w:p">
             </xsl:apply-templates>
        </xsl:otherwise>

      </xsl:choose>   

    </Document>
  </xsl:template>  

  <xsl:template match="w:p">
    <Paragraph>
      <xsl:apply-templates />
    </Paragraph>
  </xsl:template>

  <xsl:template match="w:r/w:t">
    <xsl:value-of select="." />
  </xsl:template>

</xsl:stylesheet>

我生成的输出是：

<Document>
  <Heading>
  <Paragraph>Text2-</Paragraph> 
  <Paragraph>Text5-</Paragraph> 
  </Heading>
</Document>

但我的要求输出是：

<Document>
      <Paragraph>Text1-</Paragraph> 
      <Heading>
           <Paragraph>Text2-</Paragraph> 
      </Heading>
      <Paragraph>Text3-</Paragraph> 
      <Paragraph>Text4-</Paragraph> 
      <Heading>
           <Paragraph>Text5-</Paragraph> 
      </Heading>
</Document>

我认为，我遇到阻止的问题。所以，请指导我摆脱这个问题......

Answer 1

此处 xsl：choose 的问题在于它仅被使用一次，并且只检查是否存在至少一个 w：p 元素一个标题。因此，您只能获得一个标题元素输出。为了 xsl：choose 工作，你真的需要在 w：p 模板

中使用它

<xsl:template match="w:p">
   <xsl:choose>
      <xsl:when test="w:pPr/w:pStyle[starts-with(@w:val, 'Heading')]">
         <Heading>
            <Paragraph>
               <xsl:apply-templates/>
            </Paragraph>
         </Heading>
      </xsl:when>
      <xsl:otherwise>
         <Paragraph>
            <xsl:apply-templates/>
         </Paragraph>
      </xsl:otherwise>
   </xsl:choose>
</xsl:template>

但是，你真的不需要 xsl：选择。你可以使用一个特定的模板来匹配 w：p 元素，这些元素具有匹配的 w：pPr 元素

<xsl:template match="w:p[w:pPr/w:pStyle[starts-with(@w:val, 'Heading')]]">

在此模板中，您可以输出标题元素。然后，您将有一个单独的模板来匹配所有其他 w：p 元素以输出段落，如果您给它命名，您也可以从之前的模板调用它来共享代码

<xsl:template match="w:p" name="para">

这是完整的XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:w="http://schemas.openxmlformats.org/wordprocessingml/2006/main" exclude-result-prefixes="w">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="/">
      <Document>
         <xsl:apply-templates/>
      </Document>
   </xsl:template>

   <xsl:template match="w:p[w:pPr/w:pStyle[starts-with(@w:val, 'Heading')]]">
      <Heading>
         <xsl:call-template name="para"/>
      </Heading>
   </xsl:template>

   <xsl:template match="w:p" name="para">
      <Paragraph>
         <xsl:apply-templates/>
      </Paragraph>
   </xsl:template>

   <xsl:template match="w:r/w:t">
      <xsl:value-of select="."/>
   </xsl:template>
</xsl:stylesheet>

当应用于输入XML时，输出以下内容

<Document>
   <Paragraph>Text1-</Paragraph>
   <Heading>
      <Paragraph>Text2-</Paragraph>
   </Heading>
   <Paragraph>Text3-</Paragraph>
   <Paragraph>Text4-</Paragraph>
   <Heading>
      <Paragraph>Text5-</Paragraph>
   </Heading>
</Document>

实际上，并不严格需要<xsl:template match="w:r/w:t">的最终模板，因为XSLT与没有特定模板的元素匹配时的默认行为是输出文本。

Answer 2

作为错误的一个非常简单的说明，你的xsl：otherwise块会<xsl:apply-templates select="w:p">。当时的上下文节点是根节点（/），因此这是处理作为根节点的子节点的w：p元素，并且没有这样的元素，因此它什么都不做。

你在这里处理一些非常复杂的XML，而且在XSLT方面经验很少。最好先解决一些更容易出问题的问题 - 花一些时间学习XSLT教科书或教程并完成示例。

无法使用xslt在<xsl：otherwise>块中获取某些xml元素？</xsl：otherwise>

2 个答案: