Question

我正在使用<运算符来解决Xpath 1.0中字符串的问题。

这个简单的Xpath表达式

'A' < 'B' (or the equivalent 'A' &lt; 'B')

在libxslt（这是一个XSLT 1.0引擎）的xslt运行中没有评估为true。

我检查了XML Spy，它允许在1.0和2.0中测试Xpath表达式，果然，在Xpath 2.0中它的计算结果为true，但在Xpath 1.0中，它的计算结果为false！< / p>

这是Xpath 1.0中的错误吗？

我应该使用什么其他表达式来比较两个字符串/字符的字母顺序？请注意，compare（）函数不会这样做，因为这是一个XSLT 2.0函数。

Answer 1

在XPath 1.0中，字符串比较仅针对=和!=定义，并且订购比较不可用。规范说

当要比较的对象都不是节点集而运算符是＆lt; =，＆lt;，＆gt; =或＆gt;，然后通过转换两者来比较对象对象到数字并根据IEEE 754比较数字。

因此，两个操作数都被转换为float，使它们都是NaN。

我相信Microsoft的XML添加了扩展功能来处理这个问题，但当然这只有在您使用MSXML时才有用。

Answer 2

是的，这是XPath 1.0的限制。（我不认为将你不喜欢的限制称为“错误”是合理的，尽管很明显XPath 2.0的设计者同意你这是一个不受欢迎的限制。）

您已经标记了问题“xslt”，因此您可以在XSLT级别解决问题，至少如果您的处理器具有节点集扩展名：

<xsl:variable name="nodes">
  <node><xsl:value-of select="$A"/></node>
  <node><xsl:value-of select="$B"/></node>
</xsl:variable>

<xsl:for-each select="exslt:node-set($nodes)/*">
  <xsl:sort select="."/>
  <xsl:if test="position()=1 and .=$A">A comes first!</xsl:if>
</xsl:for-each>

但也许现在是时候转向2.0了。是什么阻碍了你？

Answer 3

希望这也证明对其他人有用，下面是我按照Michael Kay的建议编写的代码。我写了一个自定义compare函数，它给出了与Xpath 2.0相同的结果。我还在问题中添加了php标记，以便更频繁地找到它。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:func="http://exslt.org/functions"
    xmlns:common="http://exslt.org/common"
    xmlns:custom="urn:myCustomFunctions"
    exclude-result-prefixes="func common custom" 
    extension-element-prefixes="func custom">

    <xsl:output method="xml"/>

    <func:function name="custom:compare">
        <xsl:param name="string1"/>
        <xsl:param name="string2"/>

        <func:result>
            <xsl:choose>
                <xsl:when test="$string1 = $string2">0</xsl:when>
                <xsl:otherwise>
                    <xsl:variable name="nodes">
                        <node><xsl:value-of select="$string1"/></node>
                        <node><xsl:value-of select="$string2"/></node>
                    </xsl:variable>
                    <xsl:for-each select="common:node-set($nodes)/*">
                        <xsl:sort select="."/>
                        <xsl:choose>
                            <xsl:when test="position()=1 and .=$string1">-1</xsl:when>
                            <xsl:when test="position()=1 and .=$string2">1</xsl:when>
                        </xsl:choose>
                    </xsl:for-each>
                </xsl:otherwise>
            </xsl:choose>
        </func:result>
    </func:function>

    <xsl:template match="/">
        <out>
            <test1><xsl:value-of select="custom:compare('A', 'B')"/></test1>
            <test2><xsl:value-of select="custom:compare('A', 'A')"/></test2>
            <test3><xsl:value-of select="custom:compare('C', 'B')"/></test3>
            <test4><xsl:value-of select="custom:compare('DD', 'A')"/></test4>
        </out>
    </xsl:template>

</xsl:stylesheet>

运行此结果（使用虚拟输入）是

<?xml version="1.0"?>
<out>
    <test1>-1</test1>
    <test2>0</test2>
    <test3>1</test3>
    <test4>1</test4>
</out>

对于那些希望自己在php中测试这个的人，这是我使用的代码：

<?php 
$xslt = new XSLTProcessor();
$xslt->importStylesheet( DOMDocument::load('testCompare.xslt') );
$xslt -> registerPHPFunctions();
$xml = new SimpleXMLElement('<test/>'); 
print $xslt->transformToXML( $xml );
?>

Answer 4

这可能是丑陋的解决方案，在许多情况下都不可行，但对于简单的字母顺序比较，您可以使用translate。以下代码段只是一个可以进一步扩展的示例：

  translate('A','ABCD','1234') &lt; translate('B','ABCD','1234');

您的翻译表达式应涵盖所有字母，大小写，并且可以通过定义命名模板方便地重复使用。

如何比较字符串与Xpath 1.0？

4 个答案: