Question

我正在尝试自定义脚本，需要使用perl从表单中获取POST值。我没有perl的背景，但这是一个相当简单的事情，所以我想这应该不难。

这是我希望在PERL中使用的代码的php版本：

<?php
$download = ($_POST['dl']) ? '1' : '0';
?>

我知道这可能与PERL版本无关，但它可以帮助我猜清楚我到底要做什么。

Answer 1

那么，在这种情况下，请看一下这个简单的代码：这会对你有帮助：

#!/usr/bin/perl
use strict;
use warnings;
use CGI;
use CGI::Carp qw(fatalsToBrowser);

sub output_top($);
sub output_end($);
sub display_results($);
sub output_form($);

my $q = new CGI;

print $q->header();

# Output stylesheet, heading etc
output_top($q);

if ($q->param()) {
    # Parameters are defined, therefore the form has been submitted
    display_results($q);
} else {
    # We're here for the first time, display the form
    output_form($q);
}

# Output footer and end html
output_end($q);

exit 0;

# Outputs the start html tag, stylesheet and heading
sub output_top($) {
    my ($q) = @_;
    print $q->start_html(
        -title => 'A Questionaire',
        -bgcolor => 'white');
}

# Outputs a footer line and end html tags
sub output_end($) {
    my ($q) = @_;
    print $q->div("My Web Form");
    print $q->end_html;
}

# Displays the results of the form
sub display_results($) {
    my ($q) = @_;

    my $username = $q->param('user_name');
}

# Outputs a web form
sub output_form($) {
    my ($q) = @_;
    print $q->start_form(
        -name => 'main',
        -method => 'POST',
    );

    print $q->start_table;
    print $q->Tr(
      $q->td('Name:'),
      $q->td(
        $q->textfield(-name => "user_name", -size => 50)
      )
    );

    print $q->Tr(
      $q->td($q->submit(-value => 'Submit')),
      $q->td('&nbsp;')
    );
    print $q->end_table;
    print $q->end_form;
}

Answer 2

样式建议：你几乎不需要为变量赋值0或1。只需在bool上下文中评估值本身。

在CGI.pm (CGI)中，param方法合并POST和GET参数，因此我们需要单独检查请求方法：

#!/usr/bin/env perl
use strict;
use warnings FATAL => 'all';
use CGI qw();
my $c = CGI->new;
print $c->header('text/plain');
if ('POST' eq $c->request_method && $c->param('dl')) {
    # yes, parameter exists
} else {
    # no
}
print 'Do not taunt happy fun CGI.';

使用Plack::Request (PSGI)，除了混合界面（body_parameters）之外，您还有不同的POST方法（query_parameters）和GET（parameters）：

#!/usr/bin/env plackup
use strict;
use warnings FATAL => 'all';
use Plack::Request qw();
my $app = sub {
    my ($env) = @_;
    my $req = Plack::Request->new($env);
    if ($req->body_parameters->get_all('dl')) {
        # yes
    } else {
        # no
    }
    return [200, [Content_Type => 'text/plain'], ['Do not taunt happy fun Plack.']];
};

Answer 3

这是一个很好的起点：The Fool's Guide to CGI.pm, the Perl module for CGI scripting。

这将显示“...如何获取POST值（来自提交的表单）并将其分配给变量。”

希望这有帮助！

Answer 4

上面的例子有点复杂。以下代码将POST值读入变量。您可以从中提取键值。如果它的GET则更好地使用CGI模块。

#!/usr/bin/perl

my $FormData = '';
read(STDIN, $FormData, $ENV{'CONTENT_LENGTH'});

## Variable $FormData holds all POST values passed

use CGI;
my $cgi = new CGI;
print $cgi->header();
print "$FormData";

如何在perl中获取POST值

4 个答案: