Question

在基类中定义类构造函数（即设置一些静态类变量）时，是否可以在派生类中重写此类构造函数，并从继承的层级父类调用构造函数

示例：

TBaseclass = class(TObject) public class constructor ClassCreate; virtual; end; TOtherClass = class(TBaseClass) public class constructor ClassCreate; override; end; **implementation** class constructor TBaseClass.ClassCreate; begin //do some baseclass stuff end; class constructor TotherClass.ClassCreate; begin inherited; //do some other stuff end;

Answer 1

class constructors没有理由是虚拟的，因为它们不能以多态方式调用。你不能直接打电话给他们;编译器根据程序中使用的类自动插入对它们的调用。虚方法用于运行时多态，但由于编译器确切地知道它在编译时调用哪些类构造函数，因此不需要对类构造函数或析构函数进行动态调度。

然而，继承不需要虚方法，因此在类构造函数或类析构函数中使用inherited应该没有问题。正如David's answer指出的那样，编译器会忽略对inherited的调用，因为多次初始化类通常是不明智的，如果你真的管理了这就是你要做的事情。调用继承的类构造函数。如果您需要两次发生某些事情，那么您需要找到一种不同的方式来实现它。

Answer 2

首先，由于类构造函数不能是虚拟的（它们不是虚拟的），您需要删除virtual和override关键字以使代码编译。

类构造函数通常用于初始化类变量。类变量通常需要初始化一次且仅一次。如果您可以按照问题中的建议方式拨打inherited，那么TBaseClass.ClassCreate会被多次调用，而实际上只需要调用一次。

虽然您可以在类构造函数中编写inherited，并且代码将编译，但编译器只是忽略它。

program ClassConstructors;

{$APPTYPE CONSOLE}

uses
  SysUtils;

var
  Count: Integer;

type
  TBaseclass = class
  public
    class constructor ClassCreate;
  end;

  TOtherClass = class(TBaseClass)
  public
    class constructor ClassCreate;
  end;

class constructor TBaseClass.ClassCreate;
begin
  inc(Count);
end;

class constructor TotherClass.ClassCreate;
begin
  inherited;
end;

begin
  TBaseClass.Create.Free;
  TOtherClass.Create.Free;
  Writeln(Count);//outputs 1
  Readln;
end.

注意，当然，两个类构造函数都会运行。

你可以覆盖一个类构造函数并使用inherited吗？

2 个答案: