Question

所以我正在使用Data.VectorSpace而我正在尝试延长force-layout。

现在我想生成一个多态'1'标量。也就是说，一个标量，如果它与一个向量相乘，将生成相同的向量，而不管该向量的类型（参数）。可能吗？有没有有用的解决方法？

这是一个更具体的代码示例（它继续使用我使用here的代码）：

data Particle v = Particle { _pos   :: Point v
                           , _vel   :: v
                           , _force :: v
                           , _mass  :: Scalar v
                           }
-- .. standalone Show and Eq omitted 
initParticle :: AdditiveGroup v => Point v -> Particle v
initParticle p = Particle p zeroV zeroV unitScalar

unitScalar = undefined

-- Should always be true:
testInit :: Point (Double,Double) -> Bool
testInit p = ((_mass (initParticle p)) == 1::Double)

如何在上面定义'unitScalar'？

Answer 1

您定义的上下文不可能;因为您说v是AdditiveGroup，所以它就是全部，因此v不能将其他属性归结为此。

您当然可以定义定义单位值的其他类：

{-# LANGUAGE FlexibleContexts #-}
module Main (main) where

import Data.VectorSpace

如果我们想要在数学上严谨，我们可能会做以下事情;但是，这在Haskell中会产生不良后果，因为只能为一个类型定义一个Monoid，所以下面的解决方案可能更好。

-- BAD SOLUTION! (Arguably)
import Data.Monoid

instance Monoid Double where
  mempty = 1
  mappend = (*)

相反，我们定义了一个通用MultiplicativeGroup，它也是乘法的幺半。

class MultiplicativeGroup a where
  unit :: a
  multiply :: a -> a -> a
  reciprocal :: a -> a

instance MultiplicativeGroup Double where
  unit = 1
  multiply = (*)
  reciprocal = (1 /)

现在我们可以实现工作示例：

data Particle v =
  Particle -- Removed Point for this example since I don't have its definition
  { _vel :: v
  , _force :: v
  , _mass :: Scalar v
  }

-- We need VectorSpace because there needs to be a Scalar type associated with v
-- Also, this context requires you to use FlexibleContexts, which should be
-- harmless
initParticle :: (VectorSpace v, MultiplicativeGroup (Scalar v))
             => Particle v
initParticle = Particle zeroV zeroV unit

-- Works as expected:
main :: IO ()
main = print $ ((_mass (initParticle :: Particle Double)) == (1::Double))

顺便说一句，您当然可以将MultiplicativeGroup替换为Num并将unit替换为1，但这会为您提供比您更多的功能可能想要。

PS。你应该看一下优秀的algebra package，它会为你更严格地做这类事情。在它上面实施力量解算器不会太难。

如何使用Data.VectorSpace生成多态“单元标量”

1 个答案: