简单方法

Question

此刻正在与Praat合作，我正在尝试编写一个脚本来执行以下操作，收集3个声音（叙述）文件。我已经管理到c），脚本部分相对容易。我没有得到的是如何将它写入包含这些列的文本文件。任何帮助都会很棒！

a）创建一个程序，提取每个叙述1-3的电话层上的所有间隔，这些间隔代表标签为单个字母的元音，保留时间。我需要每个产生的声音都有一个适当的标签，用于识别相关的元音

b）创建对应于每个间隔的Formant（burg）对象

c）计算每个Formant对象的中点

c）获取每个中点的共振峰1,2和3的值

d）使用以下标题写入文本文件：

叙述＃标签中点时间F1 F2 F3

并在其下，每个元音的适当信息

Answer 1

简单方法

最简单的方法是将输出写入Table对象，然后使用Praat的Save to comma-separated file命令将其保存到外部文件中。下面的示例使用新的（稍微合理的）新语法，因此请确保在尝试之前更新Praat（或在此答案的编辑历史记录中尝试简写版本）。

以下是一个例子：

# Create a Table with no rows
table = Create Table with column names:
..."table", 0, "Narrative Label Midpoint Time F1 F2 F3"

for i to number_of_intervals
  # Assuming you have your Formant objects in an array named "burg"
  selectObject(burg[i])
  # Run your analysis here
  # For this example, I'm assuming values for the columns are in
  # variables called narrative$, label$, midpoint, time, f1, f2 and f3

  selectObject(table)
  Append row
  current_row = Get number of rows
  # Insert your values
  Set string value:  current_row, "Narrative", narrative$
  Set string value:  current_row, "Label", label$
  Set numeric value: current_row, "Midpoint", midpoint 
  Set numeric value: current_row, "Time", time
  Set numeric value: current_row, "F1", f1 
  Set numeric value: current_row, "F2", f2
  Set numeric value: current_row, "F3", f3
endfor

# Save it!
# Remember to select it if the table is not the active selection at
# the end of the loop
Save to comma-separated file: /path/to/file
# And then you can get rid of it
removeObject(table)

或者您可以使用，如果您更喜欢标签

Save to tab-separated file: /path/to/file

请注意，此方法不允许您将“Narrative＃”作为列名。

'l33t'方式

或者，您可以~~使用Praat的文件指令~~直接写入文件，如the documentation中所述：

sep$ = ","
# sep$ = tab$

# Create / overwrite file and write header
writeFileLine: "/path/to/file",
  ..."Narrative#" + sep$ +
  ..."Label"      + sep$ + 
  ..."Midpoint"   + sep$ +
  ..."Time"       + sep$ +
  ..."F1"         + sep$ +
  ..."F2"         + sep$ +
  ..."F3"

for i to number_of_intervals
  selectObject(burg[i])
  # Run your analysis here

  appendFileLine: "/path/to/file",
    ...narrative$        + sep$ +
    ...label$            + sep$ +
    ...string$(midpoint) + sep$ +
    ...string$(time)     + sep$ + 
    ...string$(f1)       + sep$ +
    ...string$(f2)       + sep$ +
    ...string$(f3)

endfor

Answer 2

Praat用户组可以回答类似的问题here。

Praat脚本：创建文本文件

2 个答案:

简单方法

'l33t'方式