Question

我写了一个名为Document的基于Moose的简单类。此类有两个属性：name和homepage。

该类还需要提供一个名为do_something()的方法，该方法根据homepage属性检索和返回来自不同来源（如网站或不同数据库）的文本。

由于do_something()会有很多完全不同的实现，我希望将它们放在不同的包/类中，并且这些类中的每一个都应该知道它是否负责homepage属性或如果不是。

到目前为止，我的方法涉及两个角色：

package Role::Fetcher;
use Moose::Role;
requires 'do_something';
has url => (
    is => 'ro',
    isa => 'Str'
);

package Role::Implementation;
use Moose::Role;
with 'Role::Fetcher';
requires 'responsible';

一个名为Document::Fetcher的类，它为do_something()和常用方法（如HTTP GET请求）提供默认的implmentntation：

package Document::Fetcher;
use Moose;
use LWP::UserAgent;
with 'Role::Fetcher';

has ua => (
    is => 'ro',
    isa => 'Object',
    required => 1,
    default => sub { LWP::UserAgent->new }
);

sub do_something {'called from default implementation'}
sub get {
    my $r = shift->ua->get(shift);
    return $r->content if $r->is_success;
    # ...
}

通过名为responsible()的方法确定其职责的具体实施：

package Document::Fetcher::ImplA;
use Moose;
extends 'Document::Fetcher';
with 'Role::Implementation';

sub do_something {'called from implementation A'}
sub responsible { return 1 if shift->url =~ m#foo#; }

package Document::Fetcher::ImplB;
use Moose;
extends 'Document::Fetcher';
with 'Role::Implementation';

sub do_something {'called from implementation B'}
sub responsible { return 1 if shift->url =~ m#bar#; }

我的Document课程如下：

package Document;
use Moose;

has [qw/name homepage/] => (
    is => 'rw',
    isa => 'Str'
);

has fetcher => (
    is => 'ro',
    isa => 'Document::Fetcher',
    required => 1,
    lazy => 1,
    builder => '_build_fetcher',
    handles => [qw/do_something/]
);

sub _build_fetcher {
    my $self = shift;
    my @implementations = qw/ImplA ImplB/;

    foreach my $i (@implementations) {
        my $fetcher = "Document::Fetcher::$i"->new(url => $self->homepage);
        return $fetcher if $fetcher->responsible();
    }

    return Document::Fetcher->new(url => $self->homepage);
}

现在这应该可行。如果我调用以下代码：

foreach my $i (qw/foo bar baz/) {
    my $doc = Document->new(name => $i, homepage => "http://$i.tld/");
    say $doc->name . ": " . $doc->do_something;
}

我得到了预期的输出：

foo: called from implementation A
bar: called from implementation B
baz: called from default implementation

但此代码至少存在两个问题：

我需要在_build_fetcher中保留所有已知实现的列表。我更喜欢一种方法，代码会自动从命名空间Document::Fetcher::下面的每个加载的模块/类中进行选择。或者也许有更好的方式来“注册”这些插件？
目前整个代码看起来有点过于臃肿。我相信人们之前已经编写过这种插件系统。 MooseX中没有提供所需行为的东西吗？

Answer 1

您要找的是Factory，特别是Abstract Factory。 Factory类的构造函数将根据其参数确定要返回的实现。

# Returns Document::Fetcher::ImplA or Document::Fetcher::ImplB or ...
my $fetcher = Document::Fetcher::Factory->new( url => $url );

_build_fetcher中的逻辑将进入Document::Fetcher::Factory->new。这将Fetchers与您的文档分开。而不是文件知道如何确定它需要哪个Fetcher实现，Fetchers可以自己做。

如果您的优先权是允许人们添加新的Fetchers而不必更改工厂，那么让Fetcher角色能够通知工厂是否能够处理它的基本模式是好的。在不利方面，Fetcher :: Factory无法知道多个Fetchers可能对给定的URL有效，而且一个可能比另一个更好。

为了避免在Fetcher :: Factory中硬编码的Fetcher实现的大列表，让每个Fetcher角色在加载时将其自身注册到Fetcher :: Factory。

my %Registered_Classes;

sub register_class {
    my $class = shift;
    my $registeree = shift;

    $Registered_Classes{$registeree}++;

    return;
}

sub registered_classes {
    return \%Registered_Classes;
}

你可以拥有一些东西，可能是Document，如果你想要你的蛋糕也可以预先加载一堆普通的Fetchers。

Perl / Moose - 如何动态选择方法的特定实现？

1 个答案: