Question

我的输入XML包含以下内容，

<root>
    <entry>
        <type>U</type>
        <value>111</value>
    </entry>
    <entry>
        <type>X</type>
        <value>222</value>
    </entry>
    <entry>
        <type>E</type>
        <value>333</value>
    </entry>
    <entry>
        <type>Q</type>
        <value>444</value>
    </entry>
</root>

我需要输出， <ROOT> <ENTRY> <SLNO>1</SLNO> <VALUE>111</VALUE> </ENTRY> <ENTRY> <VALUE>222</VALUE> </ENTRY> <ENTRY> <VALUE>333</VALUE> </ENTRY> <ENTRY> <SLNO>2</SLNO> <VALUE>444</VALUE> </ENTRY> </ROOT>

我需要解析所有记录，但需要为类型不是X和E的记录输入序列号。

我已为同一个写了一个for-each并使用'position（）'来显示带有类型E和X的条件的序列号。所以我得到序列号为1,4而不是1,2，因为'post（）'。

我想过创建一个全局变量并在if块中增加它，但是XSLT 1.0不允许增加变量值。

我怎样才能做到这一点？

我的示例XSL代码如下：

<xsl:for-each select="/ROOT/ENTRY">
    <xsl:if test="(TYPE != 'X') and (TYPE != 'E')">             
        <xsl:text><![CDATA[<SLNO>]]></xsl:text>
        <xsl:number value="position()"/>
        <xsl:text><![CDATA[</SLNO>]]></xsl:text>
    </xsl:if>
    <!-- Printing remaining values -->
</xsl:for-each>

请帮忙。

Answer 1

您可以计算XML中前面类型元素的数量，而不是使用position（）

<xsl:value-of select="count(preceding::type[. != 'X' and . != 'E']) + 1" />

此外，您可以通过直接匹配类型元素而不是条目元素来简化当前的XSLT，然后将其替换为新的 slno 元素。

<xsl:template match="type[. != 'X' and . != 'E']">

例如，尝试以下XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="type[. != 'X' and . != 'E']">
      <slno><xsl:value-of select="count(preceding::type[. != 'X' and . != 'E']) + 1" /></slno>
   </xsl:template>

   <xsl:template match="type" />

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

当应用于您的示例XML时，输出以下内容

<root>
   <entry>
      <slno>1</slno>
      <value>111</value>
   </entry>
   <entry>
      <value>222</value>
   </entry>
   <entry>
      <value>333</value>
   </entry>
   <entry>
      <slno>2</slno>
      <value>444</value>
   </entry>
</root>

注意，我在这里使用所有小写元素名称。我不确定你的问题是否要将它们翻译成大写。

Answer 2

接受的答案是好的，除了实现的算法具有O（N ^ 2）（二次）时间复杂度并且在大输入上执行非常慢。

这是具有线性时间复杂度O（N）的转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:param name="pCount" select="0"/>
  <xsl:copy>
   <xsl:apply-templates select="node()[1]|@*">
     <xsl:with-param name="pCount" select="$pCount"/>
   </xsl:apply-templates>
  </xsl:copy>
  <xsl:apply-templates select="following-sibling::node()[1]">
     <xsl:with-param name="pCount" select="$pCount"/>
  </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="entry[not(contains('EX', type))]">
  <xsl:param name="pCount" select="0"/>

  <xsl:copy>
   <slno><xsl:value-of select="$pCount+1"/></slno>
   <xsl:apply-templates select="node()[1]|@*">
     <xsl:with-param name="pCount" select="$pCount+1"/>
   </xsl:apply-templates>
  </xsl:copy>
  <xsl:apply-templates select="following-sibling::node()[1]">
     <xsl:with-param name="pCount" select="$pCount+1"/>
  </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="type">
   <xsl:param name="pCount" select="0"/>
   <xsl:apply-templates select="following-sibling::node()[1]">
     <xsl:with-param name="pCount" select="$pCount+1"/>
   </xsl:apply-templates>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档时：

<root>
    <entry>
        <type>U</type>
        <value>111</value>
    </entry>
    <entry>
        <type>X</type>
        <value>222</value>
    </entry>
    <entry>
        <type>E</type>
        <value>333</value>
    </entry>
    <entry>
        <type>Q</type>
        <value>444</value>
    </entry>
</root>

产生了想要的正确结果：

<root>
   <entry>
      <slno>1</slno>
      <value>111</value>
   </entry>
   <entry>
      <value>222</value>
   </entry>
   <entry>
      <value>333</value>
   </entry>
   <entry>
      <slno>2</slno>
      <value>444</value>
   </entry>
</root>

<强>解释：

使用并覆盖 "fine-grained identity rule" 。它的名称源于模板一次只应用于一个节点（按文档顺序）。
修改“细粒度标识规则”以包含并传递参数$pCount，该参数包含到目前为止已达到的最大当前“序列号”。
无需返回当前序列号，因为所有entry元素都是兄弟姐妹。
时间复杂度是线性的，因为在每个节点都没有计算所有前面的兄弟节点，正如在另一个答案中所做的那样。

XSLT显示序列号

2 个答案: