Question

我试图检查另一幅图像中是否存在部分图像

说明：

完整图片
http://imageshack.us/photo/my-images/526/part1g.png/

我希望检查他是否存在于完整图片的图像的

第二部分：
http://imageshack.us/photo/my-images/706/part2p.png/

如果第二部分是Exist则函数返回true
有一个功能可以检查它是否存在？

（如果它只是单像素那么它很容易，但我想检查图像的一部分是否存在于另一个图像中）
有一个有效的代码，但它检查图像中是否存在单个像素：

    Dim bmp As Bitmap = PictureBox1.Image
    For x As Integer = 0 To bmp.Width - 1
        For y As Integer = 0 To bmp.Height - 1
            If bmp.GetPixel(x, y) = Color.FromArgb(48, 48, 48) Then
                msgbox("Pixel Exist In Image!!!")
            End If
        Next
    Next

Answer 1

我写了这个扩展名来查找图片中的图片。它有一些限制：1）图像必须保存，没有色彩空间（或相同的图像）和2）它不适用于有损压缩的图像（即.jpeg，因为你需要平均和容差实现）。

我已经优化了像素匹配例程。它没有完全调试，但似乎按预期工作。它忽略了alpha通道（故意，根据需要扩展），你需要尝试捕获你的调用者（即内存异常）。

用法：

Dim p As Point = yourBitmap.Contains(bmpYouLookFor)
If p <> Nothing Then
'...
End If

代码：如果您不希望将其作为扩展名（需要.net 3.5+），只需删除扩展属性并将其作为普通函数调用，而将源位图作为参数。< / p>

将以下内容复制并粘贴到模块中（许可证：CC-attribution）：

'*******************************************************************************
'*
'*      Epistemex
'*
'*      Bitmap extension: .Contains(bmp)
'*      KF
'*
'*      2012-09-26      Initial version
'*      2012-09-26      Minor optimization, exit for's impl.
'*
'*******************************************************************************

Imports System.Drawing
Imports System.Runtime.CompilerServices
Imports System.Drawing.Imaging
Imports System.Runtime.InteropServices

Module BitmapExtension

    <Extension()>
    Public Function Contains(src As Bitmap, ByRef bmp As Bitmap) As Point
        '
        '-- Some logic pre-checks
        '
        If src Is Nothing OrElse bmp Is Nothing Then Return Nothing

        If src.Width = bmp.Width AndAlso src.Height = bmp.Height Then
            If src.GetPixel(0, 0) = bmp.GetPixel(0, 0) Then
                Return New Point(0, 0)
            Else
                Return Nothing
            End If

        ElseIf src.Width < bmp.Width OrElse src.Height < bmp.Height Then
            Return Nothing

        End If
        '
        '-- Prepare optimizations
        '
        Dim sr As New Rectangle(0, 0, src.Width, src.Height)
        Dim br As New Rectangle(0, 0, bmp.Width, bmp.Height)

        Dim srcLock As BitmapData = src.LockBits(sr, Imaging.ImageLockMode.ReadOnly, PixelFormat.Format24bppRgb)
        Dim bmpLock As BitmapData = bmp.LockBits(br, Imaging.ImageLockMode.ReadOnly, PixelFormat.Format24bppRgb)

        Dim sStride As Integer = srcLock.Stride
        Dim bStride As Integer = bmpLock.Stride

        Dim srcSz As Integer = sStride * src.Height
        Dim bmpSz As Integer = bStride * bmp.Height

        Dim srcBuff(srcSz) As Byte
        Dim bmpBuff(bmpSz) As Byte

        Marshal.Copy(srcLock.Scan0, srcBuff, 0, srcSz)
        Marshal.Copy(bmpLock.Scan0, bmpBuff, 0, bmpSz)

        ' we don't need to lock the image anymore as we have a local copy
        bmp.UnlockBits(bmpLock)
        src.UnlockBits(srcLock)

        Dim x, y, x2, y2, sx, sy, bx, by, sw, sh, bw, bh As Integer
        Dim r, g, b As Byte

        Dim p As Point = Nothing

        bw = bmp.Width
        bh = bmp.Height

        sw = src.Width - bw      ' limit scan to only what we need. the extra corner
        sh = src.Height - bh     ' point we need is taken care of in the loop itself.

        bx = 0 : by = 0
        '
        '-- Scan source for bitmap
        '
        For y = 0 To sh
            sy = y * sStride
            For x = 0 To sw

                sx = sy + x * 3
                '
                '-- Find start point/pixel
                '
                r = srcBuff(sx + 2)
                g = srcBuff(sx + 1)
                b = srcBuff(sx)

                If r = bmpBuff(2) AndAlso g = bmpBuff(1) AndAlso b = bmpBuff(0) Then
                    p = New Point(x, y)
                    '
                    '-- We have a pixel match, check the region
                    '
                    For y2 = 0 To bh - 1
                        by = y2 * bStride
                        For x2 = 0 To bw - 1
                            bx = by + x2 * 3

                            sy = (y + y2) * sStride
                            sx = sy + (x + x2) * 3

                            r = srcBuff(sx + 2)
                            g = srcBuff(sx + 1)
                            b = srcBuff(sx)

                            If Not (r = bmpBuff(bx + 2) AndAlso
                                    g = bmpBuff(bx + 1) AndAlso
                                    b = bmpBuff(bx)) Then
                                '
                                '-- Not matching, continue checking
                                '
                                p = Nothing
                                sy = y * sStride
                                Exit For
                            End If

                        Next
                        If p = Nothing Then Exit For
                    Next
                End If 'end of region check

                If p <> Nothing Then Exit For
            Next
            If p <> Nothing Then Exit For
        Next

        bmpBuff = Nothing
        srcBuff = Nothing

        Return p

    End Function

End Module

Answer 2

您可以编写一个函数来遍历第二个图像的每个可能的左上角像素，然后将像素复制到另一个位图对象，然后将新的位图对象与第二个图像像素进行像素比较。

首先，您将遍历

处的像素

x＆lt; mainImageWidth - subImageWidth
y＆lt; mainImageHeight - subImageHeight

如果主图像中的（x，y）处的像素具有与子图像中的（0,0）处的像素相同的颜色值，则复制从（x，y）开始的区域使用类似这样的函数将尺寸作为从主图像到新Bitmap对象的子图像 - http://msdn.microsoft.com/en-us/library/aa457087.aspx

然后循环浏览新对象和子图像中的像素，比较相同坐标处的颜色。如果遇到差异，请打破循环。如果你到达这个循环的末尾，你有一个匹配并且可以返回True，否则继续循环遍历主图像的像素，直到你到达一个不能再适合子图像的点，然后返回False

Vb.Net检查图像是否存在于另一个图像中

2 个答案: