Question

如何设置颜色BLACK：0x000000是透明的，通常魔术粉色是透明的，但我想将BLACK设置为。

如果你不明白： http://j.imagehost.org/0829/WoodyGX_0.jpg

我有那个图像，当转换80x80精灵时，我希望背景是透明的，这意味着：没有背景，只有角色。

Answer 1

此时你可能会更好地将它带入Fireworks，使用魔棒选择黑色像素，删除它们，并将其保存为透明png。然后使用它。

但是，如果你想让你的生活变得比你需要的更难，你可以使用getPixel来获取所有黑色像素，然后使用setPixel将它们设置为透明。但是blitting的全部意义在于速度，而不是逐像素操作。

Answer 2

注意：如果您决定迁移到ActionScript 3，那么这是ActionScript 3中的一个答案，但对于其他人和常规信息也是如此。

您可以从源BitmapData创建新的BitmapData并删除黑色像素（转换为Alpha通道）。

我为你创造了这个功能：

// Takes a source BitmapData and converts it to a new BitmapData, ignoring
// dark pixels below the specified sensitivity.
function removeDarkness(source:BitmapData, sensitivity:uint = 10000):BitmapData
{
    // Define new BitmapData, with some size constraints to ensure the loop
    // doesn't time out / crash.
    // This is for demonstration only, consider creating a class that manages
    // portions of the BitmapData at a time (up to say 50,000 iterations per
    // frame) and then dispatches an event with the new BitmapData when done.
    var fresh:BitmapData = new BitmapData(
        Math.min(600, source.width),
        Math.min(400, source.height),
        true, 0xFFFFFFFF
    );

    fresh.lock();

    // Remove listed colors.
    for(var v:int = 0; v < fresh.height; v++)
    {
        for(var h:int = 0; h < fresh.width; h++)
        {
            // Select relevant pixel for this iteration.
            var pixel:uint = source.getPixel(h, v);

            // Check against colors to remove.
            if(pixel <= sensitivity)
            {
                // Match - delete pixel (fill with transparent pixel).
                fresh.setPixel32(h, v, 0x00000000);

                continue;
            }

            // No match, fill with expected color.
            fresh.setPixel(h, v, pixel);
        }
    }


    // We're done modifying the new BitmapData.
    fresh.unlock();


    return fresh;
}

如您所见，需要：

要从中删除较暗像素的BitmapData。
uint表示要删除的黑/灰色调的数量。

这是使用源图像的演示：

var original:Loader = new Loader();
original.load( new URLRequest("http://j.imagehost.org/0829/WoodyGX_0.jpg") );
original.contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded);


// Original image has loaded, continue.
function imageLoaded(e:Event):void
{
    // Capture pixels from loaded Bitmap.
    var obmd:BitmapData = new BitmapData(original.width, original.height, false, 0);
    obmd.draw(original);


    // Create new BitmapData without black pixels.
    var heroSheet:BitmapData = removeDarkness(obmd, 1200000);
    addChild( new Bitmap(heroSheet) );
}

如何在AS2中为导入图像设置颜色为透明度

2 个答案: