Question

my xml：要转换的输入xml

                 <content>    
                     <conditionalText name="Masked_Account_Number">
                          <text>
                             Hi 2<dynamicVariable name="asked_Account"/> is needed.
                         </text>
                     </conditionalText>

                     <dynamicInclude name="xyz" />
                </content>

所以我必须使用上面的xml，识别包含'name'作为属性的所有标签，提取它的值并创建标签'name'，在它下面，它应该有'a'标签格式如下：

包含'name'的所有标签的转换输出作为输入xml中的属性应为：

                             <name>
                                <a href="#" id="dynamicvariable" 
                                   name="value of name attribute"                   
                                   xmlns="http://www.w3.org/1999/xhtml">[value of name attribute]
                                </a>
                          </name>

仅用于输入xml文件的'dynamicVariable'标记它应该只创建'a'标记为

输入xml的'dynamicVariable'标签的转换输出应如下所示：

                      <a href="#" id="dynamicvariable" 
                                name="value of name attribute"                   
                            xmlns="http://www.w3.org/1999/xhtml">[value of name attribute]
                      </a>

所以转换后的输出xml应该看起来像

           <content1>
                     <conditionalText>
                         <text>
                           Hi 2
                           <a href="#" id="dynamicvariable" 
                               name="asked_Account"                   
                               xmlns="http://www.w3.org/1999/xhtml">[asked_Account]
                           </a>is needed
                        </text>

                         <name>
                           <a href="#" id="dynamicvariable"                                 
                             name="Masked_Account_Number"                   
                             xmlns="http://www.w3.org/1999/xhtml">[Masked_Account_Number]
                           </a>
                        </name>
                  </conditionalText>

                  <dynamicInclude>
                      <name>
                         <a href="#" id="dynamicvariable" name="xyz"                   
                            xmlns="http://www.w3.org/1999/xhtml">[xyz]
                         </a>
                     </name>
                  </dynamicIncude>
          </content1>

XSLT尝试如下：我已经拿了两个模板。第一个模板将识别包含'name'作为其属性的所有标签并提取它的值并以格式创建

                                 <name>
                                  <a href="#" id="dynamicvariable" 
                                    name="value of name attribute"                   
                                   xmlns="http://www.w3.org/1999/xhtml">[value of name attribute]
                                  </a>
                                </name>

第二个模板将覆盖第一个模板，它将仅识别名称为“dynamicVariable”的标记并提取其“name”属性值并创建格式为

的标记

                            <a 
                              href="#" id="dynamicvariable" 
                              name="value of name attribute"                   
                             xmlns="http://www.w3.org/1999/xhtml">[value of name attribute]
                            </a>

所以我的最终xslt如下：

                  <?xml version="1.0" encoding="utf-8"?>
           <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
             <xsl:output method="xml" indent="yes"/>

               <xsl:template match="content/*">
                    <content1>
                      <xsl:apply-templates />
                    </content1>
              </xsl:template>

           <xsl:template  match= "*/@name" >
                   <name>
                      <a href ='#'  id="dynamicvariable" xmlns="http://www.w3.org/1999/xhtml" >
                          <xsl:copy-of select="@*"/>
                              [<xsl:value-of select="@name"/>]
                      </a>
                  </name>

                 <xsl:for-each select="child::*">
                    <xsl:if test="name()='text'">
                          <text>
                            <xsl:apply-templates />
                           </text>
                     </xsl:if>
                  </xsl:for-each>
      </xsl:template>

                <xsl:template  match= "*[name()='dynamicVariable']" >
                  <a href ='#'  id="dynamicvariable" xmlns="http://www.w3.org/1999/xhtml" >
                     <xsl:copy-of select="@*"/>
                       [<xsl:value-of select="@name"/>]
                  </a>
                </xsl:template>

        </xsl:stylesheet>

但没有获得所需的转换xml。谁能帮我吗。然后，具有conditionalText元素的变换后的xml文件应该具有相同的子孙变换后的xml中指定的序列。

Answer 1

此转化：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*[not(name()='name')]"/>
       <xsl:apply-templates select="@name"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="*/@name">
   <name>
     <a href="#" id="dynamicvariable"
        name="{.}"
        xmlns="http://www.w3.org/1999/xhtml">[<xsl:value-of select="."/>]
     </a>
   </name>
 </xsl:template>

 <xsl:template match="dynamicVariable">
   <a href="#" id="dynamicvariable"
      name="{@name}"
      xmlns="http://www.w3.org/1999/xhtml">[<xsl:value-of select="@name"/>]
   </a>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档时：

<content>
  <conditionalText name="Masked_Account_Number">
    <text>
      Hi 2<dynamicVariable name="asked_Account"/> is needed.
    </text>
  </conditionalText>

  <dynamicInclude name="xyz" />
</content>

生成所需内容（content的重命名留给读者留下练习），结果正确：

<content>
   <conditionalText>
      <text>
      Hi 2<a xmlns="http://www.w3.org/1999/xhtml" href="#" id="dynamicvariable" name="asked_Account">[asked_Account]
   </a> is needed.
    </text>
      <name>
         <a xmlns="http://www.w3.org/1999/xhtml" href="#" id="dynamicvariable" name="Masked_Account_Number">[Masked_Account_Number]
     </a>
      </name>
   </conditionalText>
   <dynamicInclude>
      <name>
         <a xmlns="http://www.w3.org/1999/xhtml" href="#" id="dynamicvariable" name="xyz">[xyz]
     </a>
      </name>
   </dynamicInclude>
</content>

xslt需要使用'name'属性转换元素

1 个答案: