Question

我正在使用CPAN XML::LibXML模块来处理下面的XML数据。我需要确定每个元素是否都有子元素。搜索我无法找到任何例子。

<A>
    <ts>2012</ts>
    <T>M1</T>
    <T>M2</T>
    <B>
        <id>PC</id>
        <r>10</r>
        <r>30</r>
    </B>
</A>

这是我写的Perl代码

#!/usr/bin/perl

use strict;
use warnings;

use XML::LibXML;

my ($x,$elname,$haschild)= ();
my $parser = XML::LibXML->new();
my $npo    = $parser->parse_file("test.xml");
my $rootel = $npo -> getDocumentElement();
$elname = $rootel -> nodeName();
print "Root name=$elname\n";

foreach $x ($rootel->childNodes) {
    $elname = $x -> nodeName();
    $haschild = $x->hasChildNodes;
    print "Child name = $elname and has child = $haschild.\n" unless ($elname =~ /#text/i);
}

虽然我使用childNodes来浏览每个节点，但我找不到一种简单的方法来确定该节点是否有孩子。

我期望在循环遍历所有节点后得到结果：

A: Has children
ts: Has none
T: has none
T: has none
B: Has children
id: Has none
r: Has none
r: Has none

我得到的结果是这样的：

Root name=A
Child name = ts and has child = 1.
Child name = T and has child = 1.
Child name = T and has child = 1.
Child name = B and has child = 1.

在hasChildNodes条件检查后，似乎所有节点都返回true。

Answer 1

您要求的是节点的子元素的数量。子节点将包含文本和无关紧要的空格。

计算节点所具有的子元素数的最简单方法是使用findnodes('*')->size，因为XPath表达式*仅计算子元素。

以下是一些执行您所描述内容的代码

use v5.14;
use warnings;

use XML::LibXML;

my $xml = XML::LibXML->load_xml(string => <<XML);
<A>
    <ts>2012</ts>
    <T>M1</T>
    <T>M2</T>
    <B>
        <id>PC</id>
        <r>10</r>
        <r>30</r>
    </B>
</A>
XML

my $nodes = $xml->findnodes('//*');
foreach my $node ($nodes->get_nodelist) {
  my $children;
  for ($node->findnodes('*')->size) {
    $children = 'none' when 0;
    $children = '1 child' when 1;
    default { $children = "$_ children" }
  }
  printf "%s: has %s\n", $node->localname, $children;
}

<强>输出

A: has 4 children
ts: has none
T: has none
T: has none
B: has 3 children
id: has none
r: has none
r: has none

Answer 2

hasChildNodes方法怎么样？

use XML::LibXML;
my $xml = XML::LibXML->createDocument;
$xml->setDocumentElement($xml->createElement('root'));
$xml->documentElement->addChild($xml->createElement('son'));
for my $node ($xml->documentElement,
              $xml->documentElement->firstChild) {
    print $node->hasChildNodes, "\n";
}

打印

1
0

请记住，文本节点也是子节点（即节点和元素是不同的概念）。

Answer 3

如果您只需要知道子节点是否存在，那么测试：

$node->exists('*')

会比以下更有效率：

$node->findnodes('*')->size

因为它会在找到第一个节点后立即退出。

如何检测XML元素是否具有子元素

3 个答案: