Question

如何检查指定路径中是否存在节点？例如，我有这个xml：

<?xml version="1.0" encoding="UTF-8"?>
<books>
  <bookgroup name="group1">
    <book name="BookName1"/>
    <book name="BookName2"/>
    <book name="BookName3"/>
    <book name="BookName4"/>
    <book name="BookName5"/>
  </bookgroup>
  <bookgroup name="group2">
    <book name="BookName6"/>
    <book name="BookName7"/>
  </bookgroup>
  <selected>
    <book name="BookName2"/>
    <book name="BookName3"/>
  </selected>
</books>

由于子节点，欲望输出将返回true：BookName2和BookName 3存在于所选标记中，而false则因为其子节点不在所选标记中。

这就是我的尝试：

    <xsl:template name="IsChildExist">
    <xsl:param name="bookGroupName"/>
    <xsl:variable name="isExist">
        <xsl:for-each select="//bookgoup[@NAME=$bookGroupName]/book">
            <xsl:variable name="childNode" select="./@name"/>
            <xsl:choose>
                <xsl:when test="count(//selected/book[@name=$childNode])>0">
                    <xsl:value-of select="true()"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="false()"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>
    </xsl:variable>
    <xsl:value-of select="$isExist"/>
</xsl:template>

但仍然在为每个循环中的突破而战。

提前谢谢。

Answer 1

XSLT没有“打破”循环的概念。它是一种函数式语言，因此您需要在命令式语言中改变您的思维模式。

要解决您的特定问题，您可以使用密钥查找所选书籍

<xsl:key name="selected" match="selected/book" use="@name" />

您根本不需要 xsl：for-each 。您可以查找是否有任何元素列表属于某个键，而不仅仅是特定元素

<xsl:template name="IsChildExist">
  <xsl:param name="bookGroupName" select="@name"/>
  <xsl:variable name="isExist">
     <xsl:choose>
        <xsl:when test="key('selected', //bookgroup[@name=$bookGroupName]/book/@name)">
           <xsl:value-of select="true()"/>
        </xsl:when>
        <xsl:otherwise>
           <xsl:value-of select="false()"/>
        </xsl:otherwise>
     </xsl:choose>
  </xsl:variable>
  <xsl:value-of select="$isExist"/>
</xsl:template>

但是，您是否需要使用命名模板？根据您尝试输出的内容，您可以在XSLT中使用正常的模板模式匹配。试试这个XSL

<xsl:output method="xml" indent="yes"/>
   <xsl:key name="selected" match="selected/book" use="@name" />

   <xsl:template match="bookgroup[key('selected', book/@name)]">
      <bookgroup>
         <xsl:apply-templates select="@*"/>
         <xsl:text>TRUE</xsl:text>
      </bookgroup>
   </xsl:template>

   <xsl:template match="bookgroup">
      <bookgroup>
         <xsl:apply-templates select="@*"/>
         <xsl:text>FALSE</xsl:text>
      </bookgroup>
   </xsl:template>

   <xsl:template match="selected" />

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

当应用于您的示例XML时，输出以下内容：

<books>
   <bookgroup name="group1">TRUE</bookgroup>
   <bookgroup name="group2">FALSE</bookgroup>
</books>

XSLT：如果子节点存在于指定路径中，则返回true

1 个答案: