Question

我必须多次执行sumif才能解决此问题。

问题：我有一个带有零件编号的表作为第一列，对于唯一的零件它总是相同的。然而，即使对于相同的部件号（由于拼写错误等），描述1和描述2也不是完美的。我需要结合不同库存的数量：QTY AT V1，V2和V3

enter image description here

结果如果我使用多个sumif并选择首先出现描述。当然，有50k行有许多不同的PN＃。如果由于人为错误而使用sumif，则经常会出错。

我想请求帮助。比较PN＃如果它们与不同库存位置的数量相同，则描述1和2只选择最先出现的数据（如CAR - BLACK和4 WHEELS）。

有一些类似的问题和答案。但是，它们效果不佳。 Merge Cells

Answer 1

这应该可以解决您的问题。我设置了一个包含2个选项卡的工作簿：RawData和PNTotals。我创建的数据类似于示例中的两行。我有26排3种不同的PN＃s：本田，丰田和起亚。无论你有多少行和PN＃，代码都能正常工作。

运行下面的代码后，我最终在PNTotals选项卡上显示PN总计，如下所示：

HONDA   CAR - BLACK   4 WHEELS        936   516 2214
TOYOTA  CAR                           864   414 2079
KIA     CAR - RED     SPORT PACKAGE   504   204 1234

要使其生效，请将以下代码添加到模块并运行子DispatchTotalsByPNNumber()。

Option Explicit

Sub DispatchTotalsByPNNumber()
    Dim LastPN As Long

    LastPN = Sheets("RawData").Range("A1").End(xlDown).Row

    GetDistinctListOfPNNumbers (LastPN)
    GetQuantityTotalsForEachPNNumber (LastPN)

End Sub
Sub GetDistinctListOfPNNumbers(ByVal LastPN As Long)

    Sheets("PNTotals").Cells.Clear
    Sheets("RawData").Range("A2:A" & LastPN).Copy Sheets("PNTotals").Range("A1")
    Sheets("PNTotals").Range("a:a").RemoveDuplicates Columns:=1, Header:=xlNo
End Sub
Function DescCols(ByVal LastPN As Long) As Integer
    Dim i As Integer

    For i = 2 To 10 ' If you ever have more than 9 description columns, increase range here
         If Not IsNumeric(Cells(Cells(LastPN + 1, i).End(xlUp).Row, i)) Then
            DescCols = DescCols + 1
        Else
            Exit Function
        End If
    Next i
End Function

Sub GetQuantityTotalsForEachPNNumber(ByVal LastPN As Long)
    Dim i As Long
    Dim x As Integer
    Dim TotCols As Integer
    Dim PNN As String
    Dim ThisColumn As String
    Dim PNCount As Integer

    TotCols = Sheets("RawData").Range("A1").End(xlToRight).Column
    PNCount = 1
    ' get count of PN#s if there are more than 1
    If Sheets("PNTotals").Range("A2").Value <> "" Then
        PNCount = Sheets("PNTotals").Range("a1").End(xlDown).Row
    End If

    For i = 1 To PNCount
        PNN = Sheets("PNTotals").Range("A" & i).Value
        Sheets("RawData").Select
        Sheets("RawData").Range("A1").Select
        Sheets("RawData").Cells.Find(What:=PNN, after:=ActiveCell, searchorder:=xlByRows).Activate

        ' Copy description text from first instance of pn to total sheet for all description columns
        For x = 1 To DescCols(LastPN)
            Sheets("PNTotals").Cells(i, x + 1).Value = ActiveCell.Offset(, x).Value
        Next
        For x = x + 1 To TotCols
            ThisColumn = GetColumnLetter(x)
        ' set sumif formulas for however many quantity columns we have
        Sheets("PNTotals").Range(ThisColumn & i).Formula = "=SUMIF(RawData!A2:" & ThisColumn & LastPN & ",PNTotals!A" & i & ",RawData!" & ThisColumn & "2:" & ThisColumn & LastPN & ")"

        Next
    Next
End Sub

Function GetColumnLetter(ByVal ColNum As Integer) As String

    GetColumnLetter = Left(ActiveSheet.Cells(1, ColNum).Address(False, False), (ColNum <= 26) + 2)

End Function

注意：假设原始数据在RawData工作表的单元格A1中开始，并且没有任何空白的PN＃。如果有空白，则需要以不同的方式确定最后一个PN行。

使用VBA Excel将表的行与类似的值组合在一起

1 个答案: