Question

在ColdFusion 9中，有没有一种快速的方法可以找到下次计划任务试图运行的时间？

Answer 1

我宁愿调用较低级别的API，也不愿让CF计算它以通常的方式。我已经抛弃了各种服务并且看不到任何明显的方法可以帮助。

AFAIK，没有一线解决方案。 CF用于计算日期的主要方法是CronTabEntry.NextRunTime。 CronTabEntry类表示单个任务的设置。 NextRunTime方法根据任务的设置计算下一个潜在运行日期。处理过期和暂停的任务在其他地方，在运行时完成。

要复制结果，您需要调用NextRunTime并添加一些逻辑来处理过期的任务。虽然NextRunTime方法是私有的，但在Method.setAccessible(boolean)的帮助下仍然可以通过反射访问它。

我将以下功能汇总在一起进行演示。它的大部分是反射调用（在CF中比它的java等价物更冗长）。无论如何，它应该返回CF调度程序使用的相同日期。

<强>规则：

如果任务结束日期/时间已过，则返回一个emtpy字符串“”
如果是已执行的一次性任务，则返回空字符串“”
对于所有其他任务（包括暂停的任务），返回下一个计划日期

<强>用法：

result = new TaskUtil().getNextRunTime("SomeTask");
WriteDump(result);

<强> CFC

component {
     public struct function getNextRunTime(required string scheduledTaskName) {

        // load task settings from factory
        local.cron = createobject("java","coldfusion.server.ServiceFactory").getCronService();
        local.task = local.cron.findTask( arguments.scheduledTaskName );

        // abort if we cannot find the task ..
        if ( isNull(local.task) ) {
            throw ("The specified task was not found: ["& arguments.scheduledTaskName &"]");
        }     

        // Calculate the next POTENTIAL schedule date 
        local.isRecurring = listFindNoCase("daily,weekly,monthly", local.task.interval);
        local.dateClass   = createObject("java", "java.util.Date").getClass();
        local.longClass   = createObject("java", "java.lang.Long").TYPE;
        local.stringClass = createObject("java", "java.lang.String").getClass();

        // Construct the appropriate arguments 
        // Note: must load arguments / class types into arrays for java reflection 
        if (local.isRecurring) {
            local.args  = [ local.task.getStartDate(), local.task.getStartTime(), local.task.interval ];
            local.types = [ local.dateClass, local.dateClass, local.stringClass ];
        }
        else {
            local.args  = [ local.task.getStartDate(), local.task.getStartTime(), local.task.getEndTime(), javacast("long", val(local.task.interval) * 1000) ];
            local.types = [ local.dateClass, local.dateClass, local.dateClass, local.longClass ];
        }

        // Call CF's internal method to calculate the next date (UNDOCUMENTED)    
        local.internalMethod = local.task.getClass().getDeclaredMethod("NextRunTime", local.types );
        local.internalMethod.setAccessible( true );
        local.nextRunOnDate = local.internalMethod.invoke( local.task, local.args );

        // Determine if the task will be rescheduled
        local.isExpired   = false;
        if ( local.task.interval != "once" && structKeyExists( local.task, "end_date") ) {
            // It is non-recurring, so determine if it already expired
            local.expiresOnDate = local.task.mergeDates( local.task.getEndDate(), local.task.getEndTime() );
            local.isExpired   = dateCompare( local.nextRunOnDate, local.expiresOnDate, "s") >= 0;
        }
        else if ( local.task.interval == "once" && local.task.disabled) {
            // It is a one time task that already executed
            local.isExpired   = true;
        }

        // construct and return results    
        local.result = {};
        local.result.name          = local.task.task;
        local.result.isPaused    = local.task.paused;
        local.result.isExpired   = local.isExpired;
        local.result.nextRunTime = local.isExpired ? "" : local.nextRunOnDate;

        return local.result;
    }    
}

如何找到计划任务的下一个运行时间？

1 个答案: