Question

我将图像编码为ByteArray。如何将它转换为ByteArray的位图？谢谢。乌利

Answer 1

我在下面做了这个测试，效果很好。它将Bytearray转换为Bitmap。图像的格式无关紧要。 png，jpg，gif都将这些格式保存在bitmapdata类将为您解释的元数据中。保存时应使用JPEGEncoder或PNGEncoder。

        import mx.events.FlexEvent;

        public var _file:File;
        public var _stream:FileStream;
        public var _load:Loader;

        protected function init(event:FlexEvent):void {
            _file = File.desktopDirectory;
            _file.addEventListener( Event.SELECT, selectComplete);
            _file.browseForOpen( 'Image' );
        }
        private function selectComplete( event:Event ):void {
            _stream = new FileStream();
            _stream.addEventListener( Event.COMPLETE, loadComplete );
            _stream.openAsync( _file, FileMode.READ );
        }
        private function loadComplete( event:Event ):void {
            var ba:ByteArray = new ByteArray();
            _stream.readBytes( ba );
            _load = new Loader();
            _load.contentLoaderInfo.addEventListener( Event.COMPLETE, loadbytesComplete );
            _load.loadBytes( ba );
        }
        private function loadbytesComplete( event:Event ):void {
            var bit:Bitmap = _load.content as Bitmap;
            img.source = bit;
        }

Answer 2

ByteArray的格式是什么？如果像素采用32位ARGB格式，则可以创建新的BitmapData对象并使用BitmapData.setPixels()设置像素。然后只需将位图数据分配给位图对象。

如果它们不是32位ARGB格式，您可能需要先转换它们。

Answer 3

使用装载程序

import flash.display.Loader;
import flash.display.LoaderInfo;
import flash.events.Event;
import flash.display.BitmapData;
 
private function startLoad():void
{
  var loader:Loader = new Loader();
  loader.loadBytes(byteArray);
  loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loaderComplete);
}     

private function loaderComplete(event:Event):void
{
    var loaderInfo:LoaderInfo = LoaderInfo(event.target);
    var bitmapData:BitmapData = new BitmapData(loaderInfo.width, loaderInfo.height, false, 0xFFFFFF);
    bitmapData.draw(loaderInfo.loader);
    // result: bitmapData
}

Answer 4

这堂课可以帮到你： http://code.google.com/p/as3asclublib/source/browse/trunk/display/image/PNGDecoder.as?spec=svn123&r=123

Answer 5

[Bindable]
private static var m_barrLogo:ByteArray;
.
.
.
private function init_m_barrLogo():void
{
    m_barrLogo = someValue;

    // The Image below will automatically read the new value of the ByteArray and
    // display the appropriate image.
}
.
.
.
<mx:Image source="{m_barrLogo}" y="10" x="10" scaleContent="true" height="140"
        width="145"/>

AS3 - ByteArray到位图

5 个答案: