Question

我有以下程序：

procedure GetDegree(const num : DWORD ; var degree : DWORD ; min ,sec : Extended);
begin
  degree := num div (500*60*60);
  min := num div (500*60) - degree *60;
  sec := num/500 - min *60 - degree *60*60;
end;

在指定了度变量后，调试器会跳到过程的结尾。那是为什么？

Answer 1

这是一项优化。变量min和sec按值传递。这意味着调用者看不到对它们的修改，并且对此过程是私有的。因此，编译器可以确定分配给它们是没有意义的。永远不会读取分配给变量的值。因此编译器选择节省时间并跳过分配。我希望您的意思是声明这样的程序：

procedure GetDegree(const num: DWORD; var degree: DWORD; var min, sec: Extended);

正如我在上一个问题中所说，使用Extended并没有太大意义。使用其中一种标准浮点类型Single或Double会更好。甚至使用映射到Real的通用Double。

此外，您已将min声明为浮点类型，但计算会计算整数。在这方面，我对你上一个问题的回答非常准确。

我建议您创建一个记录来保存这些值。传递三个独立的变量会使您的函数接口非常混乱并破坏封装。这三个值只有在考虑整体时才有意义。

type
  TGlobalCoordinate = record
    Degrees: Integer;
    Minutes: Integer;
    Seconds: Real;
  end;

function LongLatToGlobalCoordinate(const LongLat: DWORD): TGlobalCoordinate;
begin
  Result.Degrees := LongLat div (500*60*60);
  Result.Minutes := LongLat div (500*60) - Result.Degrees*60;
  Result.Seconds := LongLat/500 - Result.Minutes*60 - Result.Degrees*60*60;
end;

function GlobalCoordinateToLongLat(const Coord: TGlobalCoordinate): DWORD;
begin
  Result := Round(500*(Coord.Seconds + Coord.Minutes*60 + Coord.Degrees*60*60));
end;

为什么编译器会跳过赋值变量

1 个答案: