Question

我有一个数组 33,32,8,100 的数组。

如何在此数组中找到最大值和最小值？

我是否需要包含任何特殊库？

Answer 1

List::Util的min和max没问题，

use List::Util qw( min max );
my $min = min @numbers;
my $max = max @numbers;

但是当你需要min和max时，List::MoreUtils的minmax更有效率（因为它的比较较少）。

use List::MoreUtils qw( minmax );
my ($min, $max) = minmax @numbers;

List :: Util是核心的一部分，但List :: MoreUtils不是。

Answer 2

您可以使用List::Util轻松完成此操作，例如

use List::Util qw(min max);
my @arr = (33, 32, 8, 100);
print min(@arr)," ", max(@arr), "\n";

Answer 3

没有模块：

#!/usr/bin/perl
use strict;
use warnings;
my @array = sort { $a <=> $b } qw(33 32 8 100);
print "min: $array[0]\n";
print "max: $array[-1]\n";

Answer 4

提供的解决方案很好，但是如果你想自己实现它，那就非常简单了：

use strict;
use warnings;

my @array = (33, 32, 8, 100);
my ($min, $max);

for (@array) {
    $min = $_ if !$min || $_ < $min;
    $max = $_ if !$max || $_ > $max
};

print "min: $min\n";
print "max: $max\n";

Answer 5

您可以使用map来执行此操作而无需库：

x*********s@x**s.com

Answer 6

您应该使用自v5.7.3以来随Perl发行版一起发布的List::Util，因此可能不需要安装。

use strict;
use warnings;

use feature 'say';

use List::Util qw/ max min /;

my @data = (33, 32, 8, 100);

say min @data;
say max @data;

<强>输出

8
100

Answer 7

当然，如果你同时想要一个列表的最大值和最小值，那么同时获取它们会更有效率;它只需要每2项数据执行3次比较，而不是4次。如果数据集足够大，这可能很重要。

List::Util不提供minmax功能但List::MoreUtils提供功能。

use strict;
use warnings;
use feature qw( say );

use List::MoreUtils qw( minmax );

my ( $min, $max ) = minmax @data;

say $min;
say $max;

Answer 8

对于数字：

    my ($min,$max) = (sort {$a <=> $b} @array)[0,-1];

对于字符串：

    my ($min,$max) = (sort {$a cmp $b} @array)[0,-1];

Answer 9

我认为List::Util正是您所寻找的。

Answer 10

您可以使用Statistics::Lite来计算最小值，最大值等

Answer 11

使用建议您熟悉的List::Util module，就像List::MoreUtils一样：

D:\ :: perl -MList::Util=max -lwe "print max 324, 43, 53, 3532, 43"
3532

D:\ :: perl -MList::Util=min -lwe "print min 324, 43, 53, 3532, 43"
43

Answer 12

List::Util具有“max”和“min”函数，您可以使用这些函数直接查找给定数字列表的最大值和最小值。检查您是否可以使用它。您也可以对数组进行排序，然后确定最高和最低数字

如何在Perl中的整数数组中找到最大值和最小值？

12 个答案: