Question

假设我有一个hashref，其Data::Dumper输出如下所示：


    $VAR1 = {
        foo_0 => 'foo_zero',
        foo_1 => 'foo_one',
        bar_0 => 'bar_zero',
        bar_1 => 'bar_one'
    }

我想基于它的键将这个哈希分成两个，如下所示，但我不知道如何做到这一点：


    $VAR1 = {
        foo_0 => 'foo_zero',
        foo_1 => 'foo_one'
    },
    $VAR2 = {
        bar_0 => 'bar_zero',
        bar_1 => 'bar_one'
    }

第一个哈希匹配/foo_[\d]/的键，而第二个哈希匹配/bar_[\d]/的键。

如果你能告诉我如何做到这一点（或者提示我一些搜索关键词），我将不胜感激
问候，
克里斯托弗史密斯

Answer 1

我假设你的哈希引用是$foo_ref。您没有说明如果您的哈希键既不是foo也不是bar会发生什么。你可以做以下三件事之一：

您必须哈希引用。其中一个foo键和一个其他键。
您丢弃既不是foo键也不是bar键的键。（这就是我所做的）。
你有第三个哈希，它存储所有非foo和非bar键。

以下计划：

#! /usr/bin/env perl

use strict;
use warnings;
use feature qw(say);
use Data::Dumper;

my $foo_re = qr/^foo_/;
my $bar_re = qr/^bar_/;

my $foo_ref = {
    foo_0 => "foo_zero",
    foo_1 => "foo_one",
    bar_0 => "bar_zero",
    bar_1 => "bar_one",
};

my $bar_ref = {};
foreach my $key (keys %{$foo_ref}) {
    if (not $key =~ $foo_re) {

    # Remove if clause to store all non-foo keys in $bar_re
    $bar_ref->{$key} = $foo_ref->{$key} if $key =~ $bar_re;
    delete $foo_ref->{$key}
    }
}

say Dumper $foo_ref;
say Dumper $bar_ref;

Answer 2

到目前为止发布的其他解决方案仍有效，但速度快而且很脏。它们需要在输入模式改变时进行更改，并且只假设两种模式。这种通用解决方案并没有受到这样的影响：它不需要改变，并且它需要任意数量的模式。

sub classify_hashref {
    my ($href, %p) = @_;
    my $r;
    for my $hkey (keys %{ $href }) {
        for my $pkey (keys %p) {
            $r->{$pkey}{$hkey} = $href->{$hkey}
                if $hkey =~ $p{$pkey};
        }
    }
    return $r;
}

my $h = {
    foo_0 => 'foo_zero',
    foo_1 => 'foo_one',
    bar_0 => 'bar_zero',
    bar_1 => 'bar_one'
};
classify_hashref($h, foo_like => qr/^foo_/, looks_like_bar => qr/^bar_/);
# {
#     looks_like_bar => {
#         bar_0 => 'bar_zero',
#         bar_1 => 'bar_one'
#     },
#     foo_like => {
#         foo_0 => 'foo_zero',
#         foo_1 => 'foo_one'
#     }
# }

Answer 3

我假设你所有的哈希键都有2个提供的模式之一。如果没有，那么您应该更准确地指定您拥有的和您期望的内容如果要处理转储的输出，我还假设它具有适合eval的正确格式。只需将您的输出放在q(和)：

中

# ...

my $VAR1;

eval q(
    $VAR1 = {
        foo_0 => 'foo_zero',
        foo_1 => 'foo_one',
        bar_0 => 'bar_zero',
        bar_1 => 'bar_one'
    }
);

my $h1 = {};
my $h2 = {};

for my $k ( keys %{$VAR1} ) {
    if ( $k =~ /foo_\d/  ) {
        $h1->{$k} = $VAR1->{$k};
        next;
    }

    $h2->{$k} = $VAR1->{$k};  # the remaining  /bar_\d/ case
}

# use your new $h1 and $h2 hasrefs
# ...

您将获得2个新的参与动作$h1和$h2 如果除了这两个案例之外还有其他案例，你应该把所有人都放在if里面，而不仅仅是第一个这不是一个完整的脚本，只是一个片段。

Perl：根据密钥将哈希拆分成几个？

3 个答案: