Question

我最近在此论坛中发布了一个question，询问有关DXE2可执行文件中缺少RTTI信息的任何建议。

该帖子是我实际案例的精简版。 RRUZ来救援，因此被剥离的版本很快得到了解决。但是，最初的问题仍然存在，所以我现在正在全力发布。 “主”：

program MissingRTTI;
{$APPTYPE CONSOLE}
uses
  System.SysUtils, RTTI, MyUnit in 'MyUnit.pas', RTTIUtil in 'RTTIUtil.pas';
var
  RHelp:  TRttiHelper;
begin
  RHelp := TRttiHelper.Create();
  if (RHelp.IsTypeFound('MyUnit.TMyClass')) then WriteLn('TMyClass was found.')
  else WriteLn('TMyClass was not found.');
  ReadLn;
  RHelp.Free();
end.

RTTIUtil.pas：

unit RTTIUtil;
interface
uses
  MyUnit;
type
  TRttiHelper = class(TObject)
  public
    function IsTypeFound(TypeName: string) : boolean;
  end;
implementation
uses
  RTTI;
function TRttiHelper.IsTypeFound(TypeName: string): boolean;
var
  rCtx:   TRttiContext;
  rType:  TRttiType;
begin
  Result := false;
  rCtx := TRttiContext.Create();
  rType := rCtx.FindType(TypeName);
  if (rType <> nil) then
    Result := true;
  rCtx.Free();
end;
end.

最后MyUnit.pas：

unit MyUnit;
interface
type
  TMyClass = class(TObject)
  end;
implementation
end.

找不到所需的类型。但是，如果我更改TRttiHelper.IsTypeFound以便它实例化（并立即释放）TMyClass的实例，则会找到该类型。像这样：

function TRttiHelper.IsTypeFound(TypeName: string): boolean;
var
  rCtx:   TRttiContext;
  rType:  TRttiType;
  MyObj:  TMyClass;
begin
  Result := false;
  MyObj:= TMyClass.Create();
  MyObj.Free();
  rCtx := TRttiContext.Create();
  ...

所以我想知道，有没有办法可以强制为TMyClass发送RTTI而不实际实例化它？

更新

另一方面，我可能会提到，如果我尝试使用TRttiContext.GetType获取TRttiType，则找到所需类型。所以有一些RTTI发出。检查由TRttiType.IsPublic检索的TRttiContext.GetType属性会产生一个真值，即检索到的类型是公共的（因此应该可以使用TRttiContext.FindType进行定位。）

Answer 1

添加对类的引用，并确保编译器/链接器不能从可执行文件中删除它。

unit MyUnit;

interface

type
  TMyClass = class(TObject)
  end;

implementation 

procedure ForceReferenceToClass(C: TClass);
begin
end;

initialization
  ForceReferenceToClass(TMyClass);

end.

在生产代码中，您可能希望将ForceReferenceToClass放在基本单元中，以便可以共享它。声明该类的单元的初始化部分是调用ForceReferenceToClass的最自然的位置，因为该单元是自包含的。

关于GetType可以找到类型的观察结果，调用GetType(TMyClass)的行为会向程序添加对类型的引用。并不是RTTI存在且FindType找不到它。相反，包含GetType(TMyClass)会将RTTI添加到生成的程序中。

如何在没有实例化的情况下确保RTTI可用于某个类？

1 个答案: