Question

我现在在工作表中使用以下宏：

With Sheets("missing_artikels")
        .Range("A1:F" & .Cells(.Rows.Count, 1).End(xlUp).Row).Copy Sheets("Master").Range("A" & Rows.Count).End(xlUp).Offset(1)
    End With

我不想将数据复制到本地文件，而是将数据复制到工作表“漏斗”中位置I:\sales\Funnel\funnel.xls的外部文件中。

我该如何结合这个？感谢。

Answer 1

这可能会给你带来一个有趣的建议，但美女从来不会写复杂的代码，而是编写简单的代码，你可以理解，即使你在说了1年之后看着它：）

始终以简单易懂的方式分解您的代码。例如，我已将您的请求与现有代码相结合。我已经声明了相关变量（参见获取lastrow，工作表名称等）

这是你在尝试的吗？

Option Explicit

Const wbPath = "I:\sales\Funnel\funnel.xls"

Sub Sample()
    Dim wbI As Workbook, wbO As Workbook
    Dim wsI As Worksheet, wsO As Worksheet
    Dim wsILrow As Long, wsOLrow As Long

    '~~> Input Workbook
    Set wbI = ThisWorkbook
    Set wsI = wbI.Sheets("missing_artikels")

    '~~> Output Workbook
    Set wbO = Workbooks.Open(wbPath)
    Set wsO = wbO.Sheets("funnel")
    wsOLrow = wsO.Range("A" & wsO.Rows.Count).End(xlUp).Row + 1

    With wsI
        wsILrow = .Range("F" & .Rows.Count).End(xlUp).Row
        .Range("A1:F" & wsILrow).Copy wsO.Range("A" & wsOLrow)
    End With

    '
    ' '~~> Rest of the code
    '
End Sub

HTH

.End（xlUp）。转到外部文件

1 个答案: