Question

我正在使用global-linum-mode作为行号。如果用不同的颜色（和/或不同的背景）突出显示当前行的行号，那将是很好的。有人知道如何实现这个目标吗？

谢谢！

Answer 1

我从我之前对Relative Line Numbers In Emacs的回答中得出了这个答案，因为它处理了在linum格式过程中记住当前行号的相同问题。

我继承linum脸，但使用hl-line的背景色。如果前景和背景不匹配，则可以使用
明确指定前景色 M-x customize-face RET my-linum-hl RET

(require 'hl-line)

(defface my-linum-hl
  `((t :inherit linum :background ,(face-background 'hl-line nil t)))
  "Face for the current line number."
  :group 'linum)

(defvar my-linum-format-string "%3d")

(add-hook 'linum-before-numbering-hook 'my-linum-get-format-string)

(defun my-linum-get-format-string ()
  (let* ((width (1+ (length (number-to-string
                             (count-lines (point-min) (point-max))))))
         (format (concat "%" (number-to-string width) "d")))
    (setq my-linum-format-string format)))

(defvar my-linum-current-line-number 0)

(setq linum-format 'my-linum-format)

(defun my-linum-format (line-number)
  (propertize (format my-linum-format-string line-number) 'face
              (if (eq line-number my-linum-current-line-number)
                  'my-linum-hl
                'linum)))

(defadvice linum-update (around my-linum-update)
  (let ((my-linum-current-line-number (line-number-at-pos)))
    ad-do-it))
(ad-activate 'linum-update)

与其他答案一样，这在生成动态宽度方面比默认dynamic格式更有效，但您可以通过注释掉(add-hook linum-before-numbering-hook 'my-linum-get-format-string)行来使用静态宽度来获得最大速度（和可选择修改my-linum-format-string的初始值以设置首选宽度。

Answer 2

可以通过hlinum扩展来实现。

(require 'hlinum)
(hlinum-activate)

您可以更改linum-highlight-face以自定义背景和前景色。

Answer 3

我不确定行号，但您可以使用global-hl-line-mode突出显示当前行。

着色当前行号

3 个答案: