Question

假设我们有一个值列表f.e. 99个值，我们讨厌使用for-each四次，每次取30个值，然后使用这些值进行操作。

<xsl:template name="30valuestemplate">   
<xsl:for-each select="values">  

   ...

</xsl:for-each>
</template>

那么如何调用这个模板4次，每次只需要30个值，或许使用一个计数器？

Answer 1

以下是XSLT执行此操作的方式：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
     <nums>
       <xsl:apply-templates/>
     </nums>
 </xsl:template>

 <xsl:template match="num[position() mod 30 = 1]">
  <group>
    <xsl:copy-of select=".|following-sibling::*[not(position() > 29)]"/>
  </group>
 </xsl:template>
 <xsl:template match="num"/>
</xsl:stylesheet>

将此转换应用于以下XML文档：

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
</nums>

生成了所需的结果（包含在单独的num元素中的每个连续的30个group元素组）：

<nums>
   <group>
      <num>01</num>
      <num>02</num>
      <num>03</num>
      <num>04</num>
      <num>05</num>
      <num>06</num>
      <num>07</num>
      <num>08</num>
      <num>09</num>
      <num>10</num>
      <num>01</num>
      <num>02</num>
      <num>03</num>
      <num>04</num>
      <num>05</num>
      <num>06</num>
      <num>07</num>
      <num>08</num>
      <num>09</num>
      <num>10</num>
      <num>01</num>
      <num>02</num>
      <num>03</num>
      <num>04</num>
      <num>05</num>
      <num>06</num>
      <num>07</num>
      <num>08</num>
      <num>09</num>
      <num>10</num>
   </group>
   <group>
      <num>01</num>
      <num>02</num>
      <num>03</num>
      <num>04</num>
      <num>05</num>
      <num>06</num>
      <num>07</num>
      <num>08</num>
      <num>09</num>
      <num>10</num>
      <num>01</num>
      <num>02</num>
      <num>03</num>
      <num>04</num>
      <num>05</num>
      <num>06</num>
      <num>07</num>
      <num>08</num>
      <num>09</num>
      <num>10</num>
      <num>01</num>
      <num>02</num>
      <num>03</num>
      <num>04</num>
      <num>05</num>
      <num>06</num>
      <num>07</num>
      <num>08</num>
      <num>09</num>
      <num>10</num>
   </group>
   <group>
      <num>01</num>
      <num>02</num>
      <num>03</num>
      <num>04</num>
      <num>05</num>
      <num>06</num>
      <num>07</num>
      <num>08</num>
      <num>09</num>
      <num>10</num>
      <num>01</num>
      <num>02</num>
      <num>03</num>
      <num>04</num>
      <num>05</num>
      <num>06</num>
      <num>07</num>
      <num>08</num>
      <num>09</num>
      <num>10</num>
      <num>01</num>
      <num>02</num>
      <num>03</num>
      <num>04</num>
      <num>05</num>
      <num>06</num>
      <num>07</num>
      <num>08</num>
      <num>09</num>
      <num>10</num>
   </group>
   <group>
      <num>01</num>
      <num>02</num>
      <num>03</num>
      <num>04</num>
      <num>05</num>
      <num>06</num>
      <num>07</num>
      <num>08</num>
      <num>09</num>
   </group>
</nums>

Answer 2

以下是将大循环划分为固定大小的部分（每次迭代限制为3次）的类似示例。它生成一个包含3列的HTML表，但您可以根据需要轻松修改它。

<xsl:template match="/"> 
............
<xsl:call-template name="list-3-groups-after">
<xsl:with-param name="n" select="1"/>
<xsl:with-param name="values" select="30valuestemplate"/>
</xsl:call-template>
.............
</xsl:template>


<xsl:template name="list-3-groups-after">
    <xsl:param name="n"/>
    <xsl:param name="values"/>
    <xsl:if test="values[$n]">
    <tr>
        <xsl:call-template name="render-value">
            <xsl:with-param name="value" select="$values[$n]"/>
        </xsl:call-template>
        <xsl:call-template name="render-value">
            <xsl:with-param name="value" select="$values[$n + 1]"/>
        </xsl:call-template>
        <xsl:call-template name="render-value">
            <xsl:with-param name="value" select="$values[$n + 2]"/>
        </xsl:call-template>
    </tr>
    <xsl:call-template name="list-3-groups-after">
        <xsl:with-param name="n" select="$n + 3"/>
        <xsl:with-param name="values" select="$values"/>
    </xsl:call-template>
    </xsl:if>
</xsl:template> 


<xsl:template name="render-value">
    <xsl:param name="value"/>
    <td valign="top">
         <xsl:value-of select="$value" />
    </td>
</xsl:template>

Answer 3

由于问题已标记为xslt-2.0，因此https://www.w3.org/TR/xslt20/#grouping上的xsl:for-each-group Dimitre's sample document使用了样式表：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
     <nums>
       <xsl:for-each-group
           select="*"
           group-starting-with="num[position() mod 30 = 1]">
         <group>
           <xsl:copy-of select="current-group()" />
         </group>
       </xsl:for-each-group>
     </nums>
 </xsl:template>
</xsl:stylesheet>

XSL：FO for-each创建固定大小的循环

3 个答案: