Question

你们知道如何使用Applescript激活第n个Google Chrome窗口吗？例如，如果我打开了三个Google Chrome窗口，那么如何激活第二个？

我尝试了很多不同的组合，例如：告诉窗口2的标签3激活

我也注意到了：

告诉应用程序“Google Chrome” 告诉窗口1激活结束告诉

和

告诉应用程序“Google Chrome” 告诉窗口2激活结束告诉

产生相同的结果，它只激活最后一个窗口打开，这是一个错误吗？

提前致谢：）

Answer 1

<强> TL;博士

使用set index of window <n> to 1并不完全有效，因为它并没有真正激活窗口 - 它确实使可见。

变通方法（示例假设您要激活窗口2）：

Yar's answer提供了一种实用的解决方法，但并不完全清楚为什么可行。但是，与以下解决方案不同，它确实具有不要求调用应用程序为authorized for assistive access的优势。

user495470's answer暗示了一个强大而通用的解决方案，该解决方案也适用于非AppleScriptable应用程序：

tell application "System Events" to tell process "Google Chrome"
    perform action "AXRaise" of window 2
    set frontmost to true
end tell

或者，使用下面定义的AppleScript处理程序：
- tell application "Google Chrome" to my activateWin(it, window 2)

虽然adayzdone's answer 应该工作且几乎，但有一个问题 - 这可能是也可能不是问题（在Chrome 21.0.1180.89上观察到Mountain Lion）[更新：从OSX 10.11.2上的Chrome 47.0.2526.106开始仍然适用]：

虽然解决方案将显示所需的窗口作为前窗，但如果之前的其他窗口处于活动状态，则Chrome将不会将其视为前窗。您可以通过非活动的关闭/缩放/缩放标题栏按钮，旁边的复选标记的窗口标题，以及Cmd-L等键盘快捷键不适用于所需窗口的事实来判断。

如果您的下一步操作是在窗口某处单击，这可能不是问题，因为这样的点击将完全激活所需的窗口。

否则，您可以采用相当强大的GUI脚本解决方法（感谢改编自通用解决方案here）：

更新：遗憾的是，实际上激活其索引设置为1的窗口的问题似乎影响了所有应用程序（在OS X 10.8.3上遇到过）。这是一个泛型函数，可以使用GUI脚本正确激活给定AppleScriptable应用程序中的给定窗口。

# Activates the specified window (w) of the specified AppleScriptable
# application (a).
    # Note that both parameters must be *objects*.
# Example: Activate the window that is currently the 2nd window in Chrome:
#   tell application "Google Chrome"
#       my activateWin(it, window 2)
#   end tell
on activateWin(a, w)
    tell application "System Events"
        click menu item (name of w) of menu 1 of menu bar item -2 ¬
                   of menu bar 1 of process (name of a)
    end tell
    activate a
end activateWin

另一方面，OP尝试了什么 - 例如，activate window 1 - 似乎在OS X 10.8.3上的所有应用程序中都被破坏了 - 而底层的应用程序被激活了，窗口规格。被忽略了。

这是原始的，更强大的教学代码：

tell application "Google Chrome"
    # Each window is represented by the title of its active tab
    # in the "Window" menu.
    # We use GUI scripting to select the matching "Window" menu item
    # and thereby properly activate the window of interest.
    # NOTE: Should there be another window with the exact same title,
    # the wrong window could be activated.

    set winOfInterest to window 2 # example
    set winTitle to name of winOfInterest

    tell application "System Events"
        # Note that we must target the *process* here.
        tell process "Google Chrome"
            # The app's menu bar.
            tell menu bar 1
                # To avoid localization issues,
                # we target the "Window" menu by position - the next-to-last
                # rather than by name.
                click menu item winTitle of menu 1 of menu bar item -2
            end tell
        end tell
    end tell
    # Finally, activate the app.
    activate
end tell

Answer 2

尝试：

tell application "Google Chrome"
    activate
    set index of window 1 to 1
    delay 3
    set index of window 2 to 1
end tell

Answer 3

正如mklement所提到的，更改索引会引发窗口，但是例如键盘快捷方式仍会被先前最前面的窗口注册。

tell application "Google Chrome"
    set index of window 2 to 1
end tell

另一种选择是将系统事件告诉AXRaise窗口1：

tell application "Google Chrome"
    set index of window 2 to 1
end tell
tell application "System Events" to tell process "Google Chrome"
    perform action "AXRaise" of window 1
end tell

Answer 4

设置索引，然后打开Chrome。

tell application "Google Chrome"
    set index of window 2 to 1
    delay 0.01
    do shell script "open -a Google\\ Chrome"
end tell

Source

Answer 5

除了有关激活所需窗口的解决方案之外，（至少）较新的Chrome版本还支持Windows active tab index属性：

tell window 1
    set active tab index to 5
end tell

Applescript - Google Chrome激活某个窗口

5 个答案: