在sas

Question

我将以下数据集作为输入

ID  
--  

1  
2  
2  
3  
4  
4  
4  
5  

需要一个新的数据集，如下所示

ID   count of ID  
--   -----------

1    1  
2    2  
3    1  
4    3  
5    1  

请问您如何使用PROC SQL在SAS中执行此操作？

Answer 1

或者Proc Freq或Proc Summary如何？这些避免了必须预先分配数据。

proc freq data=have noprint;
table id / out=want1 (drop=percent);
run;

proc summary data=have nway;
class id;
output out=want2 (drop=_type_);
run;

Answer 2

proc sql noprint;
create table test as select distinct id, count(id)
from your_table
group by ID
order by ID
;
quit;

Answer 3

试试这个：

DATA Have; 
 input id ; 
 datalines;
 1
 2
 2
 3
 4
 4
 4
 5 
 ;

Proc Sort data=Have;
 by ID;
run;

Data Want;
 Set Have;
 By ID;
 If first.ID then Count=0;
 Count+1;
 If Last.ID then Output;
Run;

Answer 4

PROC SORT DATA=YOURS NOPRINT;
  BY ID; RUN;
PROC MEANS DATA=YOURS;
  VAR ID;
  BY ID;
OUTPUT OUT=NEWDATASET N=; RUN;

您还可以选择在新数据集中仅保留Id和 N 变量。

Answer 5

我们可以使用简单的PROC SQL计数来执行此操作：

 proc sql;
 create table want as
    select id, count(id) as count_of_id 
    from have
    group by id;
 quit;

Answer 6

这是另一种可能性，通常称为DoW构造：

Data want;
  do count=1 by 1 until(last.ID);
    set have;
    by id;
    end;
run;

Answer 7

如果您想要进行的聚合很复杂，那么只使用PROC SQL，因为我们更熟悉SQL中的Group by

proc sql ;
create table solution_1 as select distinct ID, count(ID)
from table_1
group by ID
order by ID
;
quit;

OR

• 如果您使用SAS-EG Query构建器在小型中非常有用 分析。

这只是拖累和放大删除要聚合的列和摘要选项选择要执行的任何操作，如平均，计数，未命中，NMiss等。