Question

我还在学习Backbone但是我的理解是它应该处理在这种情况下自动更新视图。我的主索引视图是一个表，其中每一行都是单个模型的视图。

index_view：

Tracker.Views.Friends ||= {}

class Tracker.Views.Friends.IndexView extends Backbone.View
  template: JST["backbone/templates/friends/index"]

  initialize: () ->
    _.bindAll(this, 'addOne', 'addAll', 'render');

    @options.friends.bind('reset', this.addAll);

  addAll: () ->
    @options.friends.each(this.addOne)

  addOne: (chaser) ->
    view = new Tracker.Views.Friends.FriendView({model : friend})
    this.$("tbody").append(view.render().el)

  render: ->
    $(this.el).html(this.template(friends: this.options.friends.toJSON() ))
    @addAll()

    return this

模型和集合：

class Tracker.Models.Friend extends Backbone.Model
  paramRoot: 'friend'

  defaults:
    name: null
    status: null

class Tracker.Collections.FriendsCollection extends Backbone.Collection
  model: Tracker.Models.Friend
  url: '/friends.json'

朋友观点：

Tracker.Views.Friends ||= {}

class Tracker.Views.Friends.FriendView extends Backbone.View
  template: JST["backbone/templates/friends/friend"]

  events:
    "click .destroy" : "destroy"

  tagName: "tr"

  destroy: () ->
    @options.model.destroy()
    this.remove()

    return false

  render: ->
    $(this.el).html(this.template(this.options.model.toJSON() ))    
    return this

friend.jst.ejs：

<td><a href="javascript:void(0);" data-friendid="<%= id %>" class="friend-link"><%= name %></a></td>
<td><span class="label"><%= status %></span></td>

index.jst.ejs：

<table id="friends_table" class="table table-striped table-bordered">
    <tr>
      <td>Name</td>
      <td>Status</td>
    </tr>
</table>

我最初使用reset实例化并填充集合，如下所示：

friends = new Tracker.Collections.FriendsCollection()
friends.reset data

然后我实例化我的索引视图并将其传递给我的集合：

view = new Tracker.Views.Friends.IndexView(friends: friends)

这一切都正常，并且显示一个表，其中包含来自Web服务器的行。但是我想要定期更新服务器上发生的更改的朋友列表，所以我使用了如下的collection.fetch方法（其中updateStatus与目前描述的代码完全无关）：

window.setInterval (->
  friends.fetch success: updateStatus
), 10000

数据从fetch返回并正确解析，但它会将行附加到我的表而不是更新现有行。我该如何以我想要的方式完成这项工作？

Answer 1

重置后，您永远不会真正清除表格。

更新addAll功能以清除表格。像这样：

class Tracker.Views.Friends.IndexView extends Backbone.View
  template: JST["backbone/templates/friends/index"]

  # ...

  addAll: () ->
    @$("tbody").empty()
    @options.friends.each(this.addOne)

  # ...

请注意，根据代码/交互的复杂程度，清除这种方式可能会有点漏洞。您可能需要在每个子视图添加后保存对每个子视图的引用，然后在清除每个子视图时将其保存并调用您自定义的删除代码（如果有的话）。

您可能还需要将表头包装在index.jst.ejs文件中，以便它不会被表体的其余部分清除：

<table id="friends_table" class="table table-striped table-bordered">
    <thead>
        <tr>
          <td>Name</td>
          <td>Status</td>
        </tr>
    </thead>
</table>

Backbone fetch正在添加新行以查看而不是更新现有行

1 个答案: