Question

我有一个索引的条目，如下所示：

<entry name="a" page="1" />
<entry name="b" page="3" />
<entry name="b" page="4" />
<entry name="b" page="6" />
<entry name="c" page="7" />

现在我想得到像

这样的东西

<index name="a" pages="1 />
<index name="b" pages="3-4, 6" />
<index name="c" pages="7" />

是否有一些可以使用的功能？

我在考虑使用两遍解决方案，首先将索引条目放在

等格式中

<index name="a" pages="1 />
<index name="b" pages="3 4 6" />
<index name="c" pages="7" />

然后将“3 4 6”变成“3-4,6”。第一步很简单：

<xsl:for-each-group select="index" group-adjacent="@name">
  <xsl:element name="index">
    <xsl:attribute name="name" select="@name"/>
    <xsl:attribute name="pages" select="current-group()/@page"/>
  </xsl:element>
</xsl:for-each-group>

（这里的'页面'属性可能会有所不同，当然）

现在是困难的一步，我应该如何遍历列表？必须有一些聪明的解决方案，以检查下一个兄弟/ @页面（我可以将页面放入一个序列）是否是当前的@page + 1.

Answer 1

以下是一个示例：

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs"
  version="2.0">

  <xsl:strip-space elements="*"/>
  <xsl:output indent="yes"/>

  <xsl:template match="entries">
    <xsl:for-each-group select="entry" group-by="@name">
      <index name="{current-grouping-key()}">
        <xsl:attribute name="pages">
          <xsl:for-each-group select="current-group()/xs:integer(@page)" group-by="position() - .">
            <xsl:if test="position() gt 1">
              <xsl:text>, </xsl:text>
            </xsl:if>
            <xsl:value-of select="if (current-group()[2]) 
                                  then (current-group()[1], current-group()[last()])
                                  else ." 
                          separator="-"/>
          </xsl:for-each-group>
        </xsl:attribute>
      </index>
    </xsl:for-each-group>
  </xsl:template>

</xsl:stylesheet>

输入为

<entries>
<entry name="a" page="1" />
<entry name="b" page="3" />
<entry name="b" page="4" />
<entry name="b" page="6" />
<entry name="c" page="7" />
</entries>

我得到了结果

<index name="a" pages="1"/>
<index name="b" pages="3-4, 6"/>
<index name="c" pages="7"/>

Answer 2

这是另一种解决方案：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
      xmlns:xs="http://www.w3.org/2001/XMLSchema"
      exclude-result-prefixes="xs"      >
      <xsl:output omit-xml-declaration="yes" indent="yes"/>

      <xsl:template match="entries">
        <xsl:for-each-group select="entry" group-by="@name">
          <index name="{current-grouping-key()}">
            <xsl:attribute name="pages">
              <xsl:variable name="vAtribVals" as="xs:integer*">
                <xsl:perform-sort select="current-group()/@page/xs:integer(.)">
                  <xsl:sort data-type="number"/>
                </xsl:perform-sort>
              </xsl:variable>

              <xsl:sequence select=
                "$vAtribVals[1],
                 for $k in 2 to count($vAtribVals)
                   return
                     if($vAtribVals[$k] - $vAtribVals[$k -1] ne 1)
                       then concat(',', $vAtribVals[$k])
                       else
                         if($vAtribVals[$k+1] - $vAtribVals[$k] ne 1)
                           then concat('-', $vAtribVals[$k])
                           else()
                 "/>
            </xsl:attribute>
          </index>
        </xsl:for-each-group>
      </xsl:template>
</xsl:stylesheet>

将此转换应用于以下XML文档：

<entries>
    <entry name="a" page="1" />
    <entry name="b" page="3" />
    <entry name="b" page="4" />
    <entry name="b" page="6" />
    <entry name="c" page="7" />
</entries>

产生了想要的正确结果：

<index name="a" pages="1"/>
<index name="b" pages="3-4,6"/>
<index name="c" pages="7"/>

请注意：

在进一步处理之前对page属性进行排序，即使entry元素在源XML文档中没有按排序顺序出现，这也允许正确处理。
< / LI>
处理不依赖于整数值和位置之间的关系，这使得它适用于属性值不是整数的其他情况。

将条目组合到页码

2 个答案: