使用AutoFilter的SpecialCells在VBA中获取可见单元格时出错

Question

我的主要目标是复制自动过滤器的可见单元格，然后将可见单元格的尺寸复制到新工作表中。我正在使用此代码：

Sheets(1).AutoFilterMode = False
Sheets(1).Range("A1:A1").AutoFilter Field:=columnaNumeroIntervalo, criteria1:=CDec(paramCantidadCriterio)
Sheets(1).Range("A1:A1").AutoFilter Field:=columnaNumeroIntervaloUnidades, Criteria1:=paramUnidadesCriterio

MsgBox AutoFilter.Range.SpecialCells(xlCellTypeVisible)(2, 11).Value

在最后一行，我想检查一个单元格的值。如果我使用Cells(2,11)代替SpecialCells，我可以看到单元格包含工作表的所有单元格，可见且不可见。所以我想使用SpecialCells。

如果我使用特殊单元格，则会出现以下错误：

error '-2147417848 (80010108) in runtime. Automatization error.

对于执行类型的时间，它似乎进入循环，最后给出了这个错误。也许SpecialCells修改自动过滤器，然后在每次修改中再次执行自动过滤器？

Answer 1

要使用自动筛选的可见单元格，如果您计划排除标题，则必须使用Offset。你得到的错误是因为你错过了一个“。”在Cells(2,11)之前

'~~> Remove any filters
ActiveSheet.AutoFilterMode = False

'~~> Filter, 
With rRange 
  .AutoFilter Field:=1, Criteria1:=strCriteria

  '~~> offset(to exclude headers)
  Debug.Print .Offset(1, 0).SpecialCells(xlCellTypeVisible).Cells(2,11).Value

  Debug.Print .SpecialCells(xlCellTypeVisible).Cells(2,11).Value
End With

'~~> Remove any filters
ActiveSheet.AutoFilterMode = False

我决定将此作为此答案的一部分添加，以便将来可以帮助其他人。

假设我们的范围是

A1：F6

当您运行以下代码时，根据您是否使用Offset，您将获得这些结果。

Option Explicit

Sub Sample()
    '~~> Remove any filters
    ActiveSheet.AutoFilterMode = False

    Dim rRange As Range
    Dim Rnge As Range

    Set rRange = Sheets("Sheet1").Range("A1:F6")

    '~~> Filter,
    With rRange
      .AutoFilter Field:=1, Criteria1:="<>2"

      '~~> Offset(to exclude headers)
      Set Rnge = .Offset(1, 0).SpecialCells(xlCellTypeVisible)

      Debug.Print Range(Rnge.Address).Address
      Debug.Print ActiveSheet.Cells(3, 2).Address
      Debug.Print Range(Rnge.Address).Cells(3, 2).Address

      Debug.Print "--------------------------------------------------"

      '~~> To include headers
      Set Rnge = .SpecialCells(xlCellTypeVisible)

      Debug.Print Range(Rnge.Address).Address
      Debug.Print ActiveSheet.Cells(3, 2).Address
      Debug.Print Range(Rnge.Address).Cells(3, 2).Address

    End With

    '~~> Remove any filters
    ActiveSheet.AutoFilterMode = False
End Sub

HTH