Question

我有2个序列，一个是从1到10，另一个是1到3。如何比较第二个序列和第一个序列来测试前3个项是否相同？

Answer 1

使用此简短的XPath表达式：

deep-equal(subsequence($seq1, 1, count($seq2)), $seq2)

当评估时，如果第二个序列是第一个序列的起始子序列，它将准确生成true()。这两个序列可以包含任何XDM项目的混合，包括节点。

以下是完整演示：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>

    <xsl:variable name="vSeq1" select=
        "1, 2, 3, 4, 5, 6, 7, 8, 9, 10"/>

    <xsl:variable name="vSeq2" select=
        "1, 2, 3"/>

    <xsl:variable name="vSeq3" select="/*/*"/>
    <xsl:variable name="vSeq4" select="/*/*[position() gt 5]"/>

    <xsl:variable name="vSeq5" select="/*/*"/>
    <xsl:variable name="vSeq6" select="/*/*[position() le 5]"/>

 <xsl:template match="/">
     <xsl:sequence select=
     "deep-equal(subsequence($vSeq1, 1, count($vSeq2)), $vSeq2)"/>
     ===========
     <xsl:sequence select=
     "deep-equal(subsequence($vSeq3, 1, count($vSeq4)), $vSeq4)"/>
     ===========
     <xsl:sequence select=
     "deep-equal(subsequence($vSeq5, 1, count($vSeq6)), $vSeq6)"/>
 </xsl:template>
</xsl:stylesheet>

对以下XML文档应用此转换时：

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

产生了想要的正确结果：

 true
 ===========
 false
 ===========
 true

Answer 2

假设您有两个变量seq1和seq2，您只需测试<xsl:if test="$seq1[1] eq $seq2[1] and $seq1[2] eq $seq2[2] and $seq1[3] eq $seq2[3]">...</xsl:if>。

比较xslt中的2个序列

2 个答案: