Question

我想仅为某些特定元素更改某些属性值。例如，是否可以仅针对以下XML中价格为29.99的图书更改@lang？

<book>
  <title lang="fr">Harry Potter</title>
  <price>29.99</price>
</book>

<book>
  <title lang="eng">Learning XML</title>
  <price>39.95</price>
</book>

Answer 1

这个简短而简单的转换（根本没有明确的条件）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="book[price=29.99]/title/@lang">
  <xsl:attribute name="lang">ChangedLang</xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML （包装到格式良好的XML文档）：

<t>
    <book>
        <title lang="fr">Harry Potter</title>
        <price>29.99</price>
    </book>
    <book>
        <title lang="eng">Learning XML</title>
        <price>39.95</price>
    </book>
</t>

生成想要的正确结果：

<t>
   <book>
      <title lang="ChangedLang">Harry Potter</title>
      <price>29.99</price>
   </book>
   <book>
      <title lang="eng">Learning XML</title>
      <price>39.95</price>
   </book>
</t>

解释：覆盖所需属性的 identity rule 。

Answer 2

尝试这样的事情：

XML来源

<books>
    <book>
        <title lang="fr">Harry Potter</title>
        <price>29.99</price>
    </book>
    <book>
        <title lang="eng">Learning XML</title>
        <price>39.95</price>
    </book>
</books>

示例XSLT

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="/">
        <books>
            <xsl:for-each select="books/book">
                <xsl:apply-templates select="."/>
            </xsl:for-each>
        </books>
    </xsl:template>
    <xsl:template match="book">
            <book>
                <title>
                    <xsl:if test="price = '29.99'">
                        <xsl:attribute name="lang">eng</xsl:attribute>
                    </xsl:if>
                <xsl:value-of select="title"/></title>
                <price><xsl:value-of select="price"/></price>
            </book>
    </xsl:template>
</xsl:stylesheet>

替代模板

或者您是否真的想在匹配标题节点时使用以下兄弟轴？如果是这样可能会更好：

<xsl:template match="title">
    <title>
        <xsl:if test="following-sibling::price[1] = '29.99'">
            <xsl:attribute name="lang">eng</xsl:attribute>
        </xsl:if>
        <xsl:value-of select="."/>
    </title>
</xsl:template>

如何有条件地更改属性是检查其兄弟的值？

2 个答案: