Question

我正在寻找一些可以处理我的xml文档的正确缩进的XSLT样式表，并在http://www.printk.net/~bds/indent.html找到了非常好的样式表。

希望作者不会因为这样的引用而责怪我：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" encoding="ISO-8859-1"/>
  <xsl:param name="indent-increment" select="'   '"/>

  <xsl:template name="newline">
    <xsl:text disable-output-escaping="yes">
</xsl:text>
  </xsl:template>

  <xsl:template match="comment() | processing-instruction()">
    <xsl:param name="indent" select="''"/>
    <xsl:call-template name="newline"/>    
    <xsl:value-of select="$indent"/>
    <xsl:copy />
  </xsl:template>

  <xsl:template match="text()">
    <xsl:param name="indent" select="''"/>
    <xsl:call-template name="newline"/>    
    <xsl:value-of select="$indent"/>
    <xsl:value-of select="normalize-space(.)"/>
  </xsl:template>

  <xsl:template match="text()[normalize-space(.)='']"/>

  <xsl:template match="*">
    <xsl:param name="indent" select="''"/>
    <xsl:call-template name="newline"/>    
    <xsl:value-of select="$indent"/>
      <xsl:choose>
       <xsl:when test="count(child::*) > 0">
        <xsl:copy>
         <xsl:copy-of select="@*"/>
         <xsl:apply-templates select="*|text()">
           <xsl:with-param name="indent" select="concat ($indent, $indent-increment)"/>
         </xsl:apply-templates>
         <xsl:call-template name="newline"/>
         <xsl:value-of select="$indent"/>
        </xsl:copy>
       </xsl:when>       
       <xsl:otherwise>
        <xsl:copy-of select="."/>
       </xsl:otherwise>
     </xsl:choose>
  </xsl:template>    
</xsl:stylesheet>

除了一件令人讨厌的事情之外，它几乎完全是我想要的：它使我的文档的根元素缩进了8个空格（但不是XML声明）。结果看起来像那个标记：

<?xml version="1.0" encoding="UTF-8"?>
        <database>
           <books>
              <book id="0">
                 <ISBN value="0123456789"/>
                 <title>Some book title Language</title>
                 <hardcover value="false"/>
                 <price value="40.46"/>
                 <in_stock value="100"/>
                 <annotation>Some annotation</annotation>
              </book>
           </books>
        </database>`

我对XSLT技术很陌生，花了很多时间试图理解如何修复它，但到目前为止还没有成功。我正在使用标准的javax.xml.transform.Transformer类来进行XSLT转换。你知道为什么会这样吗？

Answer 1

您不需要任何特殊的XSLT代码来缩进。

仅使用标准身份模板， <xsl:output indent="yes"/>：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

在任何XML文档（例如此文件）上应用此转换时：

<database>            <books>
<book id="0">
<ISBN value="0123456789"/>
<title>Some book title Language</title>
              <hardcover value="false"/>
 <price value="40.46"/>
   <in_stock value="100"/>
    <annotation>Some annotation</annotation>
   </book></books> </database>

它输出相同的XML文档但缩进：

<database>
   <books>
      <book id="0">
         <ISBN value="0123456789"/>
         <title>Some book title Language</title>
         <hardcover value="false"/>
         <price value="40.46"/>
         <in_stock value="100"/>
         <annotation>Some annotation</annotation>
      </book>
   </books>
</database>

使用XSLT样式表进行奇怪的XML格式化

1 个答案: