Question

我需要在我的应用程序中生成MD5。

我试过谷歌但只找到MD5的PHP代码。我需要连接到使用MD5哈希验证的客户端系统，但是他们的代码是PHP，我的是使用VBScript的Classic ASP。

我的服务器支持.Net，因此无法使用PHP脚本。在Classic ASP中是否有任何这样的VBScript MD5代码？

Answer 1

更新2017-02-21 - 现在为JWT添加了HMACSHA256

更新2016-07-05 - 现在添加了SHA1和SHA256

是的，对于那些一直在努力解决这个问题的人（比如我自己）而且想知道，这是有可能的！

以下代码分为几个函数，以便您可以将MD5 / sha1 / sha256作为字符串或文件。

我从另一个stackexchange借用了函数GetBytes和BytesToBase64，stringToUTFBytes中的代码基于另一个stackexchange。

function md5hashBytes(aBytes)
    Dim MD5
    set MD5 = CreateObject("System.Security.Cryptography.MD5CryptoServiceProvider")

    MD5.Initialize()
    'Note you MUST use computehash_2 to get the correct version of this method, and the bytes MUST be double wrapped in brackets to ensure they get passed in correctly.
    md5hashBytes = MD5.ComputeHash_2( (aBytes) )
end function

function sha1hashBytes(aBytes)
    Dim sha1
    set sha1 = CreateObject("System.Security.Cryptography.SHA1Managed")

    sha1.Initialize()
    'Note you MUST use computehash_2 to get the correct version of this method, and the bytes MUST be double wrapped in brackets to ensure they get passed in correctly.
    sha1hashBytes = sha1.ComputeHash_2( (aBytes) )
end function

function sha256hashBytes(aBytes)
    Dim sha256
    set sha256 = CreateObject("System.Security.Cryptography.SHA256Managed")

    sha256.Initialize()
    'Note you MUST use computehash_2 to get the correct version of this method, and the bytes MUST be double wrapped in brackets to ensure they get passed in correctly.
    sha256hashBytes = sha256.ComputeHash_2( (aBytes) )
end function

function sha256HMACBytes(aBytes, aKey)
    Dim sha256
    set sha256 = CreateObject("System.Security.Cryptography.HMACSHA256")

    sha256.Initialize()
    sha256.key=aKey
    'Note you MUST use computehash_2 to get the correct version of this method, and the bytes MUST be double wrapped in brackets to ensure they get passed in correctly.
    sha256HMACBytes = sha256.ComputeHash_2( (aBytes) )
end function

function stringToUTFBytes(aString)
    Dim UTF8
    Set UTF8 = CreateObject("System.Text.UTF8Encoding")
    stringToUTFBytes = UTF8.GetBytes_4(aString)
end function

function bytesToHex(aBytes)
    dim hexStr, x
    for x=1 to lenb(aBytes)
        hexStr= hex(ascb(midb( (aBytes),x,1)))
        if len(hexStr)=1 then hexStr="0" & hexStr
        bytesToHex=bytesToHex & hexStr
    next
end function

Function BytesToBase64(varBytes)
    With CreateObject("MSXML2.DomDocument").CreateElement("b64")
        .dataType = "bin.base64"
        .nodeTypedValue = varBytes
        BytesToBase64 = .Text
    End With
End Function

'Special version that produces the URLEncoded variant of Base64 used in JWTs.
Function BytesToBase64UrlEncode(varBytes)
    With CreateObject("MSXML2.DomDocument").CreateElement("b64")
        .dataType = "bin.base64"
        .nodeTypedValue = varBytes
        BytesToBase64UrlEncode = replace(replace(replace(replace(replace(.Text,chr(13),""),chr(10),""),"+", "-"),"/", "_"),"=", "")
    End With
End Function

Function GetBytes(sPath)
    With CreateObject("Adodb.Stream")
        .Type = 1 ' adTypeBinary
        .Open
        .LoadFromFile sPath
        .Position = 0
        GetBytes = .Read
        .Close
    End With
End Function

这些可以使用如下：

BytesToBase64(md5hashBytes(stringToUTFBytes("Hello World")))

制作：sQqNsWTgdUEFt6mb5y4 / 5Q ==

bytesToHex(md5hashBytes(stringToUTFBytes("Hello World")))

产品：B10A8DB164E0754105B7A99BE72E3FE5

对于SHA1：

bytesToHex(sha1hashBytes(stringToUTFBytes("Hello World")))

产品：0A4D55A8D778E5022FAB701977C5D840BBC486D0

对于SHA256：

bytesToHex(sha256hashBytes(stringToUTFBytes("Hello World")))

产品：A591A6D40BF420404A011733CFB7B190D62C65BF0BCDA32B57B277D9AD9F146E

获取文件的MD5（对Amazon S3 MD5检查很有用）：

BytesToBase64(md5hashBytes(GetBytes(sPath)))

其中sPath是本地文件的路径。

最后，创建一个JWT：

'define the JWT header, needs to be converted to UTF bytes:
aHead=stringToUTFBytes("{""alg"":""HS256"",""typ"":""JWT""}")

'define the JWT payload, again needs to be converted to UTF Bytes.
aPayload=stringToUTFBytes("{""sub"":""1234567890"",""name"":""John Doe"",""admin"":true}") 

'Your shared key.
theKey="mySuperSecret"

aSigSource=stringToUTFBytes(BytesToBase64UrlEncode(aHead) & "." & BytesToBase64UrlEncode(aPayload))

'The full JWT correctly Base 64 URL encoded.
aJWT=BytesToBase64UrlEncode(aHead) & "." & BytesToBase64UrlEncode(aPayload) & "." & BytesToBase64UrlEncode(sha256HMACBytes(aSigSource,stringToUTFBytes(theKey)))

哪个会产生以下有效的JWT： eyJhbGciOiJIUzI1NiIsInR5cCI6IkpXVCJ9.eyJzdWIiOiIxMjM0NTY3ODkwIiwibmFtZSI6IkpvaG4gRG9lIiwiYWRtaW4iOnRydWV9.7ofvtkn0z_pTl6WcqRTxw-4eSE3NqcEq9_3ax0YcuIQ

Answer 2

感谢上面提供的所有链接，它们很有用，但是如果有人需要它，我发现这个确实很有用。 VBScript-MD5

Answer 3

这是一个可读且可下载的MD5版本作为VBS脚本：

https://github.com/Wikinaut/md5.vbs

这是来自http://chayoung.tistory.com/entry/VBScript-MD5的代码（感谢您提供这段独特的代码）。

Answer 4

我不知道这个代码是否有效，因为我无法测试它。但是，它似乎是你要求的。

http://www.bullzip.com/md5/vb/md5-vb-class.htm

以下是Jeff Attwood关于哈希的一篇有趣文章。他对MD5有一些重要的话要说：

http://www.codinghorror.com/blog/2012/04/speed-hashing.html

Answer 5

首先，谢谢SgtWilko！：）

根据您收集的信息，我为所有人完成了一项功能（不适用于base64 / Files）。
你的代码对我来说非常有用，但我正在寻找一个更像PHP的（简单）函数来处理纯文本和更明确的代码。

编辑：
根据问题How to hash a UTF-8 string in Classic ASP，我提出了ADODB.Stream解决方案。您现在可以使用非英文字符。

编辑：
参数 PlainText 已更改为目标。您现在可以使用 HMAC 版本只需将Target参数用作数组。

Target(0) = PlainText
Target(1) = SharedKey

再次感谢SgtWilko;）

Announcing the first SHA1 collision（Google安全博客）2017年2月23日。

使用此功能，您可以将纯文本哈希到：
MD5，RIPEMD160，SHA1，SHA256，SHA384，SHA512，HMACMD5，HMACRIPEMD160，HMACSHA1，HMACSHA256，HMACSHA384和HMACSHA512 如果您需要更多信息，可以在System.Security.Cryptography Namespace

中找到

Function Hash(HashType, Target)
    On Error Resume Next

    Dim PlainText

    If IsArray(Target) = True Then PlainText = Target(0) Else PlainText = Target End If

    With CreateObject("ADODB.Stream")
        .Open
        .CharSet = "Windows-1252"
        .WriteText PlainText
        .Position = 0
        .CharSet = "UTF-8"
        PlainText = .ReadText
        .Close
    End With

    Set UTF8Encoding = CreateObject("System.Text.UTF8Encoding")
    Dim PlainTextToBytes, BytesToHashedBytes, HashedBytesToHex

    PlainTextToBytes = UTF8Encoding.GetBytes_4(PlainText)

    Select Case HashType
        Case "md5": Set Cryptography = CreateObject("System.Security.Cryptography.MD5CryptoServiceProvider") '< 64 (collisions found)
        Case "ripemd160": Set Cryptography = CreateObject("System.Security.Cryptography.RIPEMD160Managed")
        Case "sha1": Set Cryptography = CreateObject("System.Security.Cryptography.SHA1Managed") '< 80 (collision found)
        Case "sha256": Set Cryptography = CreateObject("System.Security.Cryptography.SHA256Managed")
        Case "sha384": Set Cryptography = CreateObject("System.Security.Cryptography.SHA384Managed")
        Case "sha512": Set Cryptography = CreateObject("System.Security.Cryptography.SHA512Managed")
        Case "md5HMAC": Set Cryptography = CreateObject("System.Security.Cryptography.HMACMD5")
        Case "ripemd160HMAC": Set Cryptography = CreateObject("System.Security.Cryptography.HMACRIPEMD160")
        Case "sha1HMAC": Set Cryptography = CreateObject("System.Security.Cryptography.HMACSHA1")
        Case "sha256HMAC": Set Cryptography = CreateObject("System.Security.Cryptography.HMACSHA256")
        Case "sha384HMAC": Set Cryptography = CreateObject("System.Security.Cryptography.HMACSHA384")
        Case "sha512HMAC": Set Cryptography = CreateObject("System.Security.Cryptography.HMACSHA512")
    End Select

    Cryptography.Initialize()

    If IsArray(Target) = True Then Cryptography.Key = UTF8Encoding.GetBytes_4(Target(1))

    BytesToHashedBytes = Cryptography.ComputeHash_2((PlainTextToBytes))

    For x = 1 To LenB(BytesToHashedBytes)
        HashedBytesToHex = HashedBytesToHex & Right("0" & Hex(AscB(MidB(BytesToHashedBytes, x, 1))), 2)
    Next

    If Err.Number <> 0 Then Response.Write(Err.Description) Else Hash = LCase(HashedBytesToHex)

    On Error GoTo 0
End Function

这些可以使用如下：

Hash("sha512", "Hello World")

产地：
2c74fd17edafd80e8447b0d46741ee243b7eb74dd2149a0ab1b9246fb30382f27e853d8585719e0e67cbda0daa8f51671064615d645ae27acb15bfb1447f459b

Hash("sha256", "Hello World")

产地：
a591a6d40bf420404a011733cfb7b190d62c65bf0bcda32b57b277d9ad9f146e

Hash("md5", "muñeca")

产地：
ea07bec1f37f4b56ebe368355d1c058f

Hash("sha512HMAC", Array("Hello World", "Shared Key"))

产地：
28e72824c48da5a5f14b59246905d2839e7c50e271fc078b1c0a75c89b6a3998746bd8b2dc1764b19d312702cf5e15b38ce799156af28b98ce08b85e4df65b32

Answer 6

有Javascript代码可以生成MD5校验和。其中一个源自Google闭包库的是available here。

从Javascript生成Windows脚本组件非常容易，然后从任何支持COM的语言（包括VB）调用该组件。

Here's a working example

如何在经典ASP中使用VBScript生成MD5？

6 个答案: