Question

我已经能够在Classic ASP（VBScript）中找到生成 JSON的数量众多的库，但我没有找到解析的任何内容。

我想要一些我可以传递JSON字符串并返回某种类型的VBScript对象（Array，Scripting.Dictionary等）

有人可以推荐一个库来解析经典ASP中的JSON吗？

Answer 1

请记住，Classic ASP包括JScript和VBScript。有趣的是，您可以使用JScript解析JSON并直接在VBScript中使用生成的对象。

因此，可以在服务器端代码中使用规范https://github.com/douglascrockford/JSON-js/blob/master/json2.js而无需修改。

当然，如果您的JSON包含任何数组，那么在解析完成后这些数组将保留为JScript数组。您可以使用点表示法从VBScript访问JScript数组的内容。

<%@Language="VBScript" %>
<%
Option Explicit
%>

<script language="JScript" runat="server" src='path/to/json2.js'></script>

<%

Dim myJSON
myJSON = Request.Form("myJSON") // "[ 1, 2, 3 ]"
Set myJSON = JSON.parse(myJSON) // [1,2,3]
Response.Write(myJSON)          // 1,2,3
Response.Write(myJSON.[0])      // 1
Response.Write(myJSON.[1])      // 2
Response.Write(myJSON.[2])      // 3
%>

Answer 2

不确定。您是否检查过具有JSON支持的ASP extreme框架？

Answer 3

我无法得到极端进化或克里斯·尼尔森的建议。但是，以下确实对我有用：

http://tforster.wik.is/ASP_Classic_Practices_For_The_21st_Century/JSON4ASP

将以下内容下载为“json2.min.asp”

http://tforster.wik.is/@api/deki/files/2/=json2.min.asp

将以下行添加到ASP文件的顶部：

<script language="javascript" runat="server" src="json2.min.asp"></script>

然后，您可以在ASP中使用JSON。

   Dim car: Set car = JSON.parse("{""brand"":""subaru"",""model"":""outback sport"",""year"":2003," & _
                                 """colour"":""green"",""accessories"":[" & _
                                 "{""foglamps"":true},{""abs"":true},{""heatedSeats"":true}]}")

   Response.Write("brand: " & car.brand & "<br/>")                               
   Response.Write("model: " & car.model & "<br/>")                               
   Response.Write("colour: " & car.colour & "<br/>")                               
   Response.Write("has foglamps: " & CStr(car.accessories.get(0).foglamps) & "<br/>")                               

   car.accessories.get(0).foglamps = false
   Response.Write("has foglamps: " & CStr(car.accessories.get(0).foglamps) & "<br/>")                               
   Response.Write("new Json: " & JSON.stringify(car) & "<br/>")

   Set car = Nothing

注意：要解析一系列项目，您需要执行以下操作：

   for each iTmp in testing
       if (TypeName(iTmp))<>"JScriptTypeInfo" then 
           Response.Write("Item: " &  iTmp & "<br/>")
       end if
   next

Answer 4

我最近实现了一个VbsJson类，它有一个“ Decode ”方法来解析JSON到VBScript和一个“ Encode ”方法来生成JSON来自VBScript。代码有点长，所以我不在这里粘贴它。

Answer 5

http://github.com/nagaozen/asp-xtreme-evolution/

Answer 6

当我在寻找一种轻量级的纯VBScript解决方案时，我写了这个答案。

通过将基本的JSON转换为XML转换器，我们可以遍历JSON字符串并将其转换为Microsoft.XMLDOM文档。

从那里开始，我们使用Microsoft的XML API（包括XPath查询）来获取我们想要的任何值。

这可以处理简单的JSON，但是，我从来没有想过这个更复杂的答案。

对于更强大的解决方案，最好的JSON解释器，是一个合适的Javascript引擎。因此，我强烈推荐这个问题的接受答案，即Any good libraries for parsing JSON in Classic ASP?

Function JSONtoXML(jsonText)
  Dim idx, max, ch, mode, xmldom, xmlelem, xmlchild, name, value

  Set xmldom = CreateObject("Microsoft.XMLDOM")
  xmldom.loadXML "<xml/>"
  Set xmlelem = xmldom.documentElement

  max = Len(jsonText)
  mode = 0
  name = ""
  value = ""
  While idx < max
    idx = idx + 1
    ch = Mid(jsonText, idx, 1)
    Select Case mode
    Case 0 ' Wait for Tag Root
      Select Case ch
      Case "{"
        mode = 1
      End Select
    Case 1 ' Wait for Attribute/Tag Name
      Select Case ch
      Case """"
        name = ""
        mode = 2
      Case "{"
        Set xmlchild = xmldom.createElement("tag")
        xmlelem.appendChild xmlchild
        xmlelem.appendchild xmldom.createTextNode(vbCrLf)
        xmlelem.insertBefore xmldom.createTextNode(vbCrLf), xmlchild
        Set xmlelem = xmlchild
      Case "["
        Set xmlchild = xmldom.createElement("tag")
        xmlelem.appendChild xmlchild
        xmlelem.appendchild xmldom.createTextNode(vbCrLf)
        xmlelem.insertBefore xmldom.createTextNode(vbCrLf), xmlchild
        Set xmlelem = xmlchild
      Case "}"
        Set xmlelem = xmlelem.parentNode
      Case "]"
        Set xmlelem = xmlelem.parentNode
      End Select
    Case 2 ' Get Attribute/Tag Name
      Select Case ch
      Case """"
        mode = 3
      Case Else
        name = name + ch
      End Select
    Case 3 ' Wait for colon
      Select Case ch
      Case ":"
        mode = 4
      End Select
    Case 4 ' Wait for Attribute value or Tag contents
      Select Case ch
      Case "["
        Set xmlchild = xmldom.createElement(name)
        xmlelem.appendChild xmlchild
        xmlelem.appendchild xmldom.createTextNode(vbCrLf)
        xmlelem.insertBefore xmldom.createTextNode(vbCrLf), xmlchild
        Set xmlelem = xmlchild
        name = ""
        mode = 1
      Case "{"
        Set xmlchild = xmldom.createElement(name)
        xmlelem.appendChild xmlchild
        xmlelem.appendchild xmldom.createTextNode(vbCrLf)
        xmlelem.insertBefore xmldom.createTextNode(vbCrLf), xmlchild
        Set xmlelem = xmlchild
        name = ""
        mode = 1
      Case """"
        value = ""
        mode = 5
      Case " "
      Case Chr(9)
      Case Chr(10)
      Case Chr(13)
      Case Else
        value = ch
        mode = 7
      End Select
    Case 5
      Select Case ch
      Case """"
        xmlelem.setAttribute name, value
        mode = 1
      Case "\"
        mode = 6
      Case Else
        value = value + ch
      End Select
    Case 6
      value = value + ch
      mode = 5
    Case 7
      If Instr("}], " & Chr(9) & vbCr & vbLf, ch) = 0 Then
        value = value + ch
      Else
        xmlelem.setAttribute name, value
        mode = 1
        Select Case ch
        Case "}"
          Set xmlelem = xmlelem.parentNode
        Case "]"
          Set xmlelem = xmlelem.parentNode
        End Select
      End If
    End Select
  Wend

  Set JSONtoXML = xmlDom
End Function

上面的脚本转换了以下JSON：

{
  "owningSystemUrl": "http://www.arcgis.com",
  "authInfo": {
    "tokenServicesUrl": "https://www.arcgis.com/sharing/rest/generateToken",
    "isTokenBasedSecurity": true
  }
}

成：

<xml owningSystemUrl="http://www.arcgis.com">
    <authInfo
        tokenServicesUrl="https://www.arcgis.com/sharing/rest/generateToken"
        isTokenBasedSecurity="true" >
    </authInfo>
</xml>

我们现在可以使用XPath来提取tokenServicesUrl，例如：

dom.SelectSingleNode("xml/authInfo").getAttribute("tokenServicesUrl")
' Returns: "https://www.arcgis.com/sharing/rest/generateToken"

Answer 7

AX是一个很棒的库，但如果你只需要JSON处理功能，它就会很重。

但是，我确实从AX项目中获取了base.asp文件和json.asp类文件，并成功使用它们在我的项目中实现JSON解析。

对于JSON生成，我发现aspjson更易于集成。它还具有更强大的json相关功能。 ax文档有点缺乏，并且更多的工作要集成到项目中，但是它确实很好地将其JSON VB对象序列化回字符串。

Answer 8

这里的解决方案非常好但有时候有点矫枉过正。如果JSON很简单并且总是相同的结构，你可以自己解析它，它快速而简单。

 'read data from client
 records = Request.Form("records")
 'convert the JSON string to an array
 Set oRegExpre = new RegExp
 oRegExpre.Global = true
 oRegExpre.Pattern = "[\[\]\{\}""]+"
 records = replace(records, "},{","||")
 records = oRegExpre.Replace(records, "" )
 aRecords = split(records,"||")
 'iterate the array and do some cleanup
 for each rec in aRecords
   aRecord = split(rec,",")
   id          = split(aRecord(1),":")(1)
   field       = split(aRecord(0),":")(0)
   updateValue = split(aRecord(0),":")(1)
   updateValue = replace(updateValue,chr(10),"\n")
   updateValue = replace(updateValue,chr(13),"\r")
   updateValue = replace(updateValue,"'","''")
  'etc
next

在Classic ASP中解析JSON的任何好库？

有人可以推荐一个库来解析经典ASP中的JSON吗？

8 个答案: