Question

警告：背景信息非常长。如果您认为在背景信息之前需要问题，请跳到底部。感谢这将要花费的时间！

我一直在网上（阅读谷歌），我没有找到一个好的答案。是的，在erlang.org网站上有很多关于Mnesia文档的链接和参考，但即使这些链接也受到版本的影响。

因此，在最简单的情况下，您当前连接的节点（）与表集的所有者相同，然后备份/恢复将起作用。例如：

$ erl -sname mydatabase

> mnesia:start().
> mnesia:create_schema(...).
> mnesia:create_table(...).
> mnesia:backup("/tmp/backup.bup").
> mnesia:restore("/tmp/backup.bup", [{default_op, recreate_tables}]).

嘿，这很棒！

但是，如果数据库实际上是在远程接口上的远程节点（）或远程节点（）上运行，那么您必须以这种方式启动备份：

$ erl -sname mydbadmin

> rpc:call(mydatabase@host, mnesia, backup, ["/tmp/backup.bup"]).
> rpc:call(mydatabase@host, mnesia, restore, ["/tmp/backup.bup", [{default_op, recreate_tables}]]).

当然这也很简单。现在这里是棘手的事情......

假设您正在进行每日备份。你的mnesia数据库服务器死了，你被迫更换硬件。如果要按原样恢复数据库，则需要使用与以前相同的名称命名新硬件，并且还需要将节点命名为相同。
如果要更改硬件和/或节点（）的名称...或者要在其他计算机上还原，则需要执行node_change过程。（描述here和mnesia docs）

但现在情况变得复杂了。虽然我的熟人是erlang和mnesia专家，他们认为mnesia的复制存在严重缺陷，你不应该使用它（目前我还没有其他替代方案，你有什么机会实现更好的版本;不是可能）

所以你有两个节点（）复制ram和基于光盘的表。您一直在使用默认的BackupMod维护使用标准备份定期备份数据库的策略。有一天，经理会要求您验证备份。只有当您尝试恢复数据库时，才能获得：

{atomic,[]}

根据文档，这意味着没有错误......但是没有表格被恢复。

不想运行change_node过程，您还记得node（）和hostname必须匹配，因此您更改主机名和-sname参数以匹配备份数据的计算机。但是这次你得到一个奇怪的错误：

{aborted,{'EXIT',{aborted,{bad_commit,{missing_lock,mydatabase@otherhost}}}}}

仍然不想运行change_node程序我快速克隆恢复我的服务器，以便我有两台类似的机器。然后我恰当地命名以匹配生产服务器。然后我开始恢复过程。找到了！我现在在恢复服务器上有真实的工作数据。

我想说这是路的尽头......但我还没有问过一个问题，而且问题的重点......所以这就是它？

问题：如果我想恢复从复制的mnesia节点集群中获取的备份，我该如何修改文件（类似于change_node过程），以便其他节点要么忽略或从备份中删除？

问题略有不同：如何在单个节点（）上恢复复制多节点（）mnesia数据库？

Answer 1

我认为这个问题属于与简单问题相关的更广泛的Mnesia问题类别：

如何重命名Mnesia节点？

第一个也是最简单的解决方案，如果你的数据库不是很大，那就是使用mnesia：traverse_backup函数（参见Mnesia User guide）。以下是Mnesia用户指南中的示例：

change_node_name(Mod, From, To, Source, Target) ->
    Switch =
        fun(Node) when Node == From -> To;
           (Node) when Node == To -> throw({error, already_exists});
           (Node) -> Node
        end,
    Convert =
        fun({schema, db_nodes, Nodes}, Acc) ->
                {[{schema, db_nodes, lists:map(Switch,Nodes)}], Acc};
           ({schema, version, Version}, Acc) ->
                {[{schema, version, Version}], Acc};
           ({schema, cookie, Cookie}, Acc) ->
                {[{schema, cookie, Cookie}], Acc};
           ({schema, Tab, CreateList}, Acc) ->
                Keys = [ram_copies, disc_copies, disc_only_copies],
                OptSwitch =
                    fun({Key, Val}) ->
                            case lists:member(Key, Keys) of
                                true -> {Key, lists:map(Switch, Val)};
                                false-> {Key, Val}
                            end
                    end,
                {[{schema, Tab, lists:map(OptSwitch, CreateList)}], Acc};
           (Other, Acc) ->
                {[Other], Acc}
        end,
    mnesia:traverse_backup(Source, Mod, Target, Mod, Convert, switched).

view(Source, Mod) ->
    View = fun(Item, Acc) ->
                   io:format("~p.~n",[Item]),
                   {[Item], Acc + 1}
           end,
    mnesia:traverse_backup(Source, Mod, dummy, read_only, View, 0).

这里最重要的部分是操作{schema, db_nodes, Nodes}元组，它允许你重命名或替换数据库节点。

顺便说一下，我过去曾经使用过这个功能，我注意到的一件事是mnesia版本之间的备份术语格式发生了变化，但也许只是我写错了代码。如果您想确定，只需打印小型mnesia数据库的备份日志以检查备份术语格式。

希望这有帮助！

Answer 2

我很难让它正常工作，所以我将分享我所经历的步骤。

首先备份要还原的分布式系统中的节点（到单个节点）：

> mnesia:backup("/path/to/backup").

确保要还原到的节点上可以使用change_node_name的以下改编版本：

-module(move_backup).
-export([set_node_name/4]).                                                                                                    

set_node_name(From, To, Source, Target) ->
    Switch =
        fun (Nodes) ->
                case lists:member(From, Nodes) of
                    true -> [To];
                    false -> []
                end
        end,
    Convert =
        fun({schema, db_nodes, Nodes}, Acc) ->
                {[{schema, db_nodes, Switch(Nodes)}], Acc};
           ({schema, version, Version}, Acc) ->
                {[{schema, version, Version}], Acc};
           ({schema, cookie, Cookie}, Acc) ->
                {[{schema, cookie, Cookie}], Acc};
           ({schema, Tab, CreateList}, Acc) ->
                Keys = [ram_copies, disc_copies, disc_only_copies],
                OptSwitch =
                    fun({Key, Val}) ->
                            case lists:member(Key, Keys) of
                                true -> {Key, Switch(Val)};
                                false-> {Key, Val}
                            end
                    end,
                {[{schema, Tab, lists:map(OptSwitch, CreateList)}], Acc};
           (Other, Acc) ->
                {[Other], Acc}
        end,
    mnesia:traverse_backup(Source, Target, Convert, switched).

转换备份：

> move_backup:set_node_name('before@host', 'after@host', "/path/to/backup", "/path_to_backup_converted").

我将假设新节点完全为空（如果不是这种情况，则可能需要更改default_op参数）。有两种选择，一种是实时还原：

> mnesia:restore("/path/to/backup_converted", [{default_op, recreate_tables}]).

很棒，但是如果您有大型数据库（我的〜10GB可能会导致内存不足异常），则可能会使用大量内存。另一种方法是安装一个后备，然后重新启动您的shell：

> mnesia:install_fallback("/path/to/backup_converted").
> q().

然后，当您重新启动外壳程序（假设您使用正确的节点名称）时，它将导入完整的数据库。

备份/恢复mnesia数据库的正确方法是什么？

2 个答案: