Question

我正在将用户定义的查询转换为SPARQL。例如，当用户说“abc”时，它意味着给我一个给定类型的所有节点，这些节点具有一些名为“abc”的属性。作为对此的扩展，如果用户说“abc或（pqr和lmn）”，我需要找到某个属性为“abc或（pqr和lmn）”的给定类型的所有节点。以下是我提出的查询：

SELECT DISTINCT ?node, ?type                                                 
WHERE                                                                          
{
  {                                                                              
    ?node a ?type .                                                          
    FILTER ( ?type != <sometype>)
  }
{           
  {                                                                              
    ?node ?reln0 ?obj0 .                                                     
    FILTER ( regex(str(?obj0), 'abc', "i") )                           
  }                                                                              
  UNION                                                                          
  {                                                                              
    {                                                                              
      ?node ?reln1 ?obj1 .                                                     
      FILTER ( regex(str(?obj1), 'pqr', "i") )                                
    }
    {                                                                             
      ?node ?reln2 ?obj2 .                                                     
      FILTER ( regex(str(?obj2), 'lmn', "i") )                               
    }                                                                              
  }
}                                                                              
}                                                                              
ORDER BY ?node

但它没有返回正确的结果。上面给出的查询有问题吗？我不想使用以下内容，因为我需要动态生成条件，每个子句都需要分开。

FILTER (regex(str(?obj2), 'abc', "i") || regex(str(?obj2), 'pqr', "i") && regex(str(?obj2), 'lmn', "i"))

Answer 1

我使您的查询具体如下（为第一个过滤器设置一个明确的类型）：

PREFIX : <http://example.org/>

SELECT DISTINCT ?node ?type                                                 
WHERE                                                                          
{
    {                                                                              
        ?node a ?type .                                                          
        FILTER ( ?type != :Type1 )
    }
    {           
        {                                                                              
            ?node ?reln0 ?obj0 .                                                     
            FILTER ( regex(str(?obj0), 'abc', "i") )                           
        }                                                                              
        UNION                                                                          
        {                                                                              
            {                                                                              
                ?node ?reln1 ?obj1 .                                                     
                FILTER ( regex(str(?obj1), 'pqr', "i") )                                
            }
            {                                                                             
                ?node ?reln2 ?obj2 .                                                     
                FILTER ( regex(str(?obj2), 'lmn', "i") )                               
            }                                                                              
        }
    }                                                                              
}                                                                              
ORDER BY ?node

然后我生成了以下数据：

@prefix : <http://example.org/> .

:n1 a :Type2 ;    # keep
    :r0 :NodeABC .

:n2 a :Type2 ;
    :r0 :NodeBCD .

:n3 a :Type2 ;     # keep
    :r1 :NodePQR ;
    :r2 :NodeLMN .

:n4 a :Type2 ;
    :r1 :NodeQRS ;
    :r2 :NodeLMN .

:n5 a :Type2 ;
    :r1 :NodePQR ;
    :r2 :NodeMNO .

:n6 a :Type2 ;
    :r1 :NodeQRS ;
    :r2 :NodeMNO .

只应保留:n1和:n3。我可以使用Jena's command line ARQ或Redland based roqet运行此功能，并且在这两种情况下都会获得这些规则。

使用ARQ：

$ arq --data data.n3 --query query.sparql
-----------------
| node | type   |
=================
| :n1  | :Type2 |
| :n3  | :Type2 |
-----------------

$ arq --version
Jena:       VERSION: 2.10.0
Jena:       BUILD_DATE: 2013-02-20T12:04:26+0000
ARQ:        VERSION: 2.10.0
ARQ:        BUILD_DATE: 2013-02-20T12:04:26+0000

使用roqet：

$ roqet query.sparql -D data.n3 -r table
roqet: Querying from file query.sparql
--------------------------------------------------------------
| node                       | type                          |
==============================================================
| uri<http://example.org/n1> | uri<http://example.org/Type2> |
| uri<http://example.org/n3> | uri<http://example.org/Type2> |
--------------------------------------------------------------

$ roqet -v
0.9.28

使用SPARQL查询的UNION和交集

1 个答案: