Question

有没有办法可以使用as3来访问iPad的相机？

我的意思是在应用程序内启动相机
有能力拍摄并将图像保存到byteArray并将图像应用到背景或进行一些操作

我做了一些研究，大部分只是展示了如何访问Android设备。感谢您的任何建议或帮助。

Answer 1

是的，你绝对可以这样做。 Flash的优点在于，执行此操作的代码与您在Android或PC上使用的代码相同。

从字面上看，您可以将相机连接到Video对象：

var camera:Camera = Camera.getCamera();
var video=new Video();
video.attachCamera(camera);
this.addChild(video); // 'this' would be a Sprite or UIComponent, etc...

如果你想做一些有用的事情，还有很多事情要做，但是一旦你开始它就会非常直接：）

Answer 2

bluebill1049，如果你得到了你想要的东西，我不确定，但我确实看到了你对整个班级的要求。我在这篇文章中找到了相同的信息（Jason Sturges在他的回答中发布）。

take photo using Adobe Builder (flex) for iOS

与他在这里的回复不同，他对该帖子的回复有一个关于构建移动应用程序的精彩教程的链接，并且从该教程开始，该代码被解除/引用。它需要一个包含在该项目/教程中的事件类（event.CameraEvent - 只有几行），因此能够返回源代码是很重要的。该来源位于：

http://devgirl.org/files/RIAUnleashed/

我要感谢杰森。只是这样你就不必去挖掘，这里是引用中缺少的事件类：

package events
{
    import flash.events.Event;
    import flash.filesystem.File;

    public class CameraEvent extends Event
    {
        public static const FILE_READY:String = "fileReady";

        public var file:File;

        public function CameraEvent(type:String, file:File=null, bubbles:Boolean = true, cancelable:Boolean = true)
        {
            super(type, bubbles, cancelable);
            this.file = file;
        }
    }
}

希望有所帮助！

Answer 3

使用加载程序不是访问iOS上图像字节的唯一方法。事实证明，数据已经是JPEG格式，因此无需再次编码。

只需执行mediaPromise.open()即可获取字节并直接保存它们。

Answer 4

XpenseIt示例代码提供了此相机实现：

类：CameraUtil：

package utils
{
    import events.CameraEvent;

    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import flash.events.MediaEvent;
    import flash.filesystem.File;
    import flash.filesystem.FileMode;
    import flash.filesystem.FileStream;
    import flash.media.CameraRoll;
    import flash.media.CameraUI;
    import flash.media.MediaPromise;
    import flash.media.MediaType;
    import flash.utils.ByteArray;

    import mx.events.DynamicEvent;
    import mx.graphics.codec.JPEGEncoder;

    [Event(name = "fileReady", type = "events.CameraEvent")]
    public class CameraUtil extends EventDispatcher
    {
        protected var camera:CameraUI;
        protected var loader:Loader;
        public var file:File;

        public function CameraUtil()
        {
            if (CameraUI.isSupported)
            {
                camera = new CameraUI();
                camera.addEventListener(MediaEvent.COMPLETE, mediaEventComplete);
            }
        }

        public function takePicture():void
        {
            if (camera)
                camera.launch(MediaType.IMAGE);
        }

        protected function mediaEventComplete(event:MediaEvent):void
        {
            var mediaPromise:MediaPromise = event.data;
            if (mediaPromise.file == null)
            {
                // For iOS we need to load with a Loader first
                loader = new Loader();
                loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loaderCompleted);
                loader.loadFilePromise(mediaPromise);
                return;
            }
            else
            {
                // Android we can just dispatch the event that it's complete
                file = new File(mediaPromise.file.url);
                dispatchEvent(new CameraEvent(CameraEvent.FILE_READY, file));
            }
        }

        protected function loaderCompleted(event:Event):void
        {
            var loaderInfo:LoaderInfo = event.target as LoaderInfo;
            if (CameraRoll.supportsAddBitmapData)
            {
                var bitmapData:BitmapData = new BitmapData(loaderInfo.width, loaderInfo.height);
                bitmapData.draw(loaderInfo.loader);
                file = File.applicationStorageDirectory.resolvePath("receipt" + new Date().time + ".jpg");
                var stream:FileStream = new FileStream()
                stream.open(file, FileMode.WRITE);
                var j:JPEGEncoder = new JPEGEncoder();
                var bytes:ByteArray = j.encode(bitmapData);
                stream.writeBytes(bytes, 0, bytes.bytesAvailable);
                stream.close();
                trace(file.url);
                dispatchEvent(new CameraEvent(CameraEvent.FILE_READY, file));
            }
        }

    }
}

as3 Adobe Air访问iPad设备相机

4 个答案:

as3 Adob​​e Air访问iPad设备相机

4 个答案:

as3 Adobe Air访问iPad设备相机