Question

我在Groovy [a: 1, b: 2]和[b:1, c:3]中有两张地图，并希望从中创建第三张地图[a: 1, b: 3, c: 3]。是否有Groovy命令可以做到这一点？

编辑：请注意，如果密钥相同，则第三个地图中的值是前两个地图中的值的总和。

由于

Answer 1

另一个解决方案是：

def m1 = [ a:1, b:2 ]
def m2 = [ b:1, c:3 ]

def newMap = [m1,m2]*.keySet().flatten().unique().collectEntries {
  [ (it): [m1,m2]*.get( it ).findAll().sum() ]
}

以epidemian's answer为灵感，您还可以编写一个处理多个地图的方法

def m1 = [a: 1, b: 2]
def m2 = [b: 1, c: 3]

def combine( Map... m ) {
  m.collectMany { it.entrySet() }.inject( [:] ) { result, e ->
    result << [ (e.key):e.value + ( result[ e.key ] ?: 0 ) ]
  }
}

def newMap = combine( m1, m2 )

Answer 2

这适用于任意数量的地图：

def maps = [[a: 1, b: 2], [b:1, c:3]]

def result = [:].withDefault{0}
maps.collectMany{ it.entrySet() }.each{ result[it.key] += it.value }

assert result == [a: 1, b: 3, c: 3]

maps.collectMany{ it.entrySet() }表达式返回一个映射条目列表，如[a=1, b=2, b=1, c=3]，然后将每个映射条目添加到结果中。

另一种选择，如果你想将所有转换保持在一个表达式并使其“更具功能性”，那就是首先按键对条目进行分组然后对值求和，但我认为它的可读性较差：

def result = maps.collectMany{ it.entrySet() }
    .groupBy{ it.key }
    .collectEntries{[it.key, it.value.sum{ it.value }]}

groupBy部分返回[a:[a=1], b:[b=2, b=1], c:[c=3]]形式的地图，然后collectEntries将地图转换为具有相同kays但具有值中列表总和的另一个地图代替。

Answer 3

以下示例演示了将两个地图添加到第三个地图m3：

Map m1 = [ a:1, b:2 ];
Map m2 = [ b:1, c:3 ];
Map m3 = [:];
m3 << m1
m3 << m2

Answer 4

一种很好的方法是使用扩展运算符：

def m1 = [ a:1, b:2 ]
def m2 = [ b:1, c:3 ]
def m3 = [ *:m1, *:m2 ]

println "m1 = $m1"
println "m2 = $m2"
println "m3 = $m3"

*信用卡：http://mrhaki.blogspot.ch/2009/09/groovy-goodness-spread-operator.html

上面的代码在groovysh中不起作用，但在groovy控制台中它很好。（对于版本1.8）

Answer 5

我认为没有现成的方法，可能会使用类似的东西：

def m1 = [a: 1, b: 2]
def m2 = [b: 1, c: 3]
def newMap = (m1.keySet() + m2.keySet()).inject([:]) { 
    acc, k -> acc[k] = (m1[k] ?: 0) + (m2[k] ?: 0); acc 
}

Answer 6

这样做：

Map additionJoin( Map map1, Map map2 )
{
  def result = [:];
  result.putAll( map1 );
  result.putAll( map2 );

  result.each { key, value ->
    if( map1[key] && map2[key] )
    {
      result[key] = map1[key] + map2[key]
    }
  }

  return result;
}

def a = [a: 1, b: 2]
def b = [b:1,c:3]

def c = additionJoin( a, b )

println c

Answer 7

def merge(map1, map2) { 
    def add = { map, entry -> map << entry }
    map2.inject(map1.inject([:], add), add)
}

在Groovy中添加两个映射，同时汇总公共键的值

7 个答案: